Delete blank node from ontology through SPARQL UPDATE

问题

I am storing some data in my ontology model made in protege with help of a SPARQL UPDATE 'insert' operation. Below is the update query.

PREFIX test: <http://www.semanticweb.org/muhammad/ontologies/2017/2/untitled-ontology-14#>
insert {
  [] test:Kpi_Variable ?s ;
     test:hasValue_ROB4 ?p ;
     test:hasTime ?now .
}
where {

    values (?s ?p) {
        (test:Actual_Production_Time 33)
    }
    bind (now() as ?now)
}

It stores in the rdf graph in the following way:

[ test:Kpi_Variable   test:Actual_Production_Time ;
  test:hasTime        "2017-06-02T14:40:33.187+03:00"^^xsd:dateTime ;
  test:hasValue_ROB4  33
] .

Now I want to delete this blank node with the 'delete' operation. I have tried many ways but that didn't work. Any Suggestions?

回答1:

Using DELETE:

PREFIX test: <http://www.semanticweb.org/muhammad/ontologies/2017/2/untitled-ontology-14#>

DELETE
  {
  ?b  test:Kpi_Variable ?s ;
      test:hasValue_ROB4 ?p ;
      test:hasTime ?t .
  }
WHERE
  {
  ?b  test:Kpi_Variable ?s ;
      test:hasValue_ROB4 ?p ;
      test:hasTime ?t .
  FILTER (?t < now())
  FILTER (isBlank(?b))
  # ...
  VALUES (?s ?p) { (test:Actual_Production_Time 33) }
  }

Using DELETE WHERE:

PREFIX test: <http://www.semanticweb.org/muhammad/ontologies/2017/2/untitled-ontology-14#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
DELETE
WHERE
  {
  ?s  test:Kpi_Variable test:Actual_Production_Time ;
      test:hasValue_ROB4 33 ;
      test:hasTime "2017-06-00T00:00:00.000+00:00"^^xsd:dateTime . 
  }

Blank nodes and blank node labels (as well as FILTER etc.) can not be used in DELETE WHERE.

来源：https://stackoverflow.com/questions/44330216/delete-blank-node-from-ontology-through-sparql-update