Excel: dynamically calculate range next to a searched up cell

问题

I am an occasional Excel user and stuck how to create a dynamic range.

After looking up a text in a table, how can I calculate the range next to this cell, up to the next empty row? Not using VBA.

Thanks for your help.

回答1:

In H4, formula copied down :

=IFERROR(INDEX(INDEX(C:C,MATCH(F4,A:A,0)):C$1000,MATCH(G4,INDEX(B:B,MATCH(F4,A:A,0)):B$1000,0)),"")

Should you want a dynamic range,

Change C$1000 to INDEX(C:C,MATCH(9.9E+307,B:B)

and

Change B$1000 to INDEX(B:B,MATCH(9.9E+307,B:B))

Then

The H4 copied down formula become :

=IFERROR(INDEX(INDEX(C:C,MATCH(F4,A:A,0)):INDEX(C:C,MATCH(9.9E+307,B:B)),MATCH(G4,INDEX(B:B,MATCH(F4,A:A,0)):INDEX(B:B,MATCH(9.9E+307,B:B)),0)),"")

Edit :

As per Ron Rosenfeld's comment, "should B11 change to 24 and G4 change to 24"

The "Source Table" set up in Excel Table type for dynamic range growing purpose

and

The H4 formula change to :

=IFERROR(LOOKUP(9^9,Table1[price]/(LOOKUP(ROW(Table1[texture]),ROW(Table1[texture])/(Table1[texture]<>""),Table1[texture])=F4)/(Table1[length]=G4)),"")

回答2:

Combining the Index() and Match() functions usually works well when using two conditions. However, you will need to fill out the entire column A with the "texture" list in order for the below formula to work.

=INDEX(<P1>, MATCH(TRUE, (<T1>=<T2>) + (<L1>=<L2>) > 1,0))

• Where <P1> is your entire price column (ex. C2:C15)
• Where <T1> is your entire texture column (ex. A2:A15)
• Where <T2> is your texture lookup value cell
• Where <L1> is your entire length column (ex. B2:B15)
• Where <L2> is your length lookup value cell

---

Let's say that you input your texture value into cell F3, and your length value into cell F4. With the remaining columns remaining as they are in your image, you would use the following formula:

=INDEX(C2:C15, MATCH(TRUE, (A2:A15=F3) + (B2:B15=F4) > 1,0))

---

Now last time I had to use Index/Match I thought I had to place the formula into an array. However, the above seems to work without it.

If you notice that it's not working as expected, you can place into an array formula by clicking the cell that contains the formula, then clicking the formula box at the top. While in the formula box, simultaneously press Ctrl + Shift + Return. This should then place curly brackets around your entire formula if done properly, as such:

回答3:

If you have O365 with the SEQUENCE function, you can use, for price:

=IF(G4="","",VLOOKUP(G4,INDEX($B:$C,SEQUENCE(MATCH(TRUE,ISBLANK(INDEX($B:$B,MATCH(F4,$A:$A,0)):INDEX(B:B,ROWS(B:B)-MATCH(F4,$A:$A,0))),0)-1,,MATCH(F4,$A:$A,0)),{1,2}),2,FALSE))

explanation:

• get starting row:

  MATCH(F4,$A:$A,0)
  

• ending row will be the first blank row after the starting row:

  MATCH(TRUE,ISBLANK(INDEX($B:$B,MATCH(F4,$A:$A,0)):INDEX(B:B,ROWS(B:B)-MATCH(F4,$A:$A,0))),0)
  

• Construct the relevant array:

  INDEX($B:$C,SEQUENCE(MATCH(TRUE,ISBLANK(INDEX($B:$B,MATCH(F4,$A:$A,0)):INDEX(B:B,ROWS(B:B)-MATCH(F4,$A:$A,0))),0)-1,,MATCH(F4,$A:$A,0)),{1,2})
  

  • The above might reduce (with wavy) to:

      index(b:c,{9,10,11},{1,2}
    

Then it's just a matter of applying the VLOOKUP

A more understandable, but longer with more operations, formula available in O365 makes use of LET. The advantage is that one can use names which indicate what each section of the formula does.

For example:

=IF(G4="","",LET(startRow,MATCH(F4,$A:$A,0),numRows,MATCH(TRUE,ISBLANK(INDEX($B:$B,startRow):INDEX($B:$B,ROWS($B:$B)-startRow)),0)-1,
       arr,INDEX($B:$C,SEQUENCE(numRows,,startRow),{1,2}),price,XLOOKUP(G4,INDEX(arr,0,1),INDEX(arr,0,2)),price))

Or, using VLOOKUP

=IF(G4="","",VLOOKUP(G4,LET(startRow,MATCH(F4,$A:$A,0),numRows,MATCH(TRUE,ISBLANK(INDEX($B:$B,startRow):INDEX($B:$B,ROWS($B:$B)-startRow)),0)-1,arr,INDEX($B:$C,SEQUENCE(numRows,,startRow),{1,2}),arr),2,FALSE))

Finally, for earlier versions of Excel, you can use this whopper where we replace the SEQUENCE function with a construct like: ROW(INDEX(A:A,firstRow):INDEX(A:A,lastRow))

=IF(G4="","",VLOOKUP(G4,INDEX($B:$C,ROW(INDEX($A:$A,MATCH(F4,$A:$A,0)):INDEX($A:$A,MATCH(F4,$A:$A,0)+MATCH(TRUE,INDEX($B:$B,MATCH(F4,$A:$A,0)):INDEX($B:$B,ROWS($B:$B))="",0)-2)),{1,2}),2,FALSE))

来源：https://stackoverflow.com/questions/65459826/excel-dynamically-calculate-range-next-to-a-searched-up-cell