Trouble listing printers with Excel VBA

问题

So here's the original problem:

I have an Excel file with a button that runs a macro. This macro needs to print the sheet to 2 separate network printers. The workbook will be run on multiple different computers on the network.

My current code looks like so:

Application.ActivePrinter = "Printer-A on Ne02:"
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False
Application.ActivePrinter = "Printer-B on Ne05:"
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False

The problem lies with the on Ne02: and on Ne05:. These values differ from one computer to another. E.g.:

Printer-A on Ne03:
Printer-B on Ne02:
Printer-A on Ne07:
etc

I can circumvent the issue by displaying the "select a printer" dialog and forcing users to choose the printer manually, but I would prefer for this to be automatic.

I have tried using the Windows Script Host Object Model to list all of the printers like so:

Function FindPrinter(name As String)
    Dim nwo As New WshNetwork
    Dim i As Integer
    Dim fullName As String

    For i = 0 To (nwo.EnumPrinterConnections.Count / 2) - 1
        If InStr(nwo.EnumPrinterConnections(i * 2 + 1), name) > 0 Then
            fullName = nwo.EnumPrinterConnections(i * 2 + 1)
        End If
    Next i

    ' Returns the LAST printer that matches
    FindPrinter = fullName
End Function

Sub MyMacro()
    ActivePrinter = FindPrinter("Printer-A")
End Sub

However this fails. If I look at the output of FindPrinter, it's only returning the string "Printer-A" without the "on Ne02:"

How can I get a full list of printers installed, including this "on NeXX:" bit? Or, alternatively, how can I set a printer as active knowing only its name?

回答1:

Run the Test sub at the bottom:

Option Explicit
Private Const HKEY_CURRENT_USER As Long = &H80000001
Private Const HKCU = HKEY_CURRENT_USER
Private Const KEY_QUERY_VALUE = &H1&
Private Const ERROR_NO_MORE_ITEMS = 259&
Private Const ERROR_MORE_DATA = 234

Private Declare Function RegOpenKeyEx Lib "advapi32" _
    Alias "RegOpenKeyExA" ( _
    ByVal HKey As Long, _
    ByVal lpSubKey As String, _
    ByVal ulOptions As Long, _
    ByVal samDesired As Long, _
    phkResult As Long) As Long

Private Declare Function RegEnumValue Lib "advapi32.dll" _
    Alias "RegEnumValueA" ( _
    ByVal HKey As Long, _
    ByVal dwIndex As Long, _
    ByVal lpValueName As String, _
    lpcbValueName As Long, _
    ByVal lpReserved As Long, _
    lpType As Long, _
    lpData As Byte, _
    lpcbData As Long) As Long

Private Declare Function RegCloseKey Lib "advapi32.dll" ( _
    ByVal HKey As Long) As Long

Public Function GetPrinterFullNames() As String()
Dim Printers() As String ' array of names to be returned
Dim PNdx As Long    ' index into Printers()
Dim HKey As Long    ' registry key handle
Dim Res As Long     ' result of API calls
Dim Ndx As Long     ' index for RegEnumValue
Dim ValueName As String ' name of each value in the printer key
Dim ValueNameLen As Long    ' length of ValueName
Dim DataType As Long        ' registry value data type
Dim ValueValue() As Byte    ' byte array of registry value value
Dim ValueValueS As String   ' ValueValue converted to String
Dim CommaPos As Long        ' position of comma character in ValueValue
Dim ColonPos As Long        ' position of colon character in ValueValue
Dim M As Long               ' string index

' registry key in HCKU listing printers
Const PRINTER_KEY = "Software\Microsoft\Windows NT\CurrentVersion\Devices"

PNdx = 0
Ndx = 0
' assume printer name is less than 256 characters
ValueName = String$(256, Chr(0))
ValueNameLen = 255
' assume the port name is less than 1000 characters
ReDim ValueValue(0 To 999)
' assume there are less than 1000 printers installed
ReDim Printers(1 To 1000)

' open the key whose values enumerate installed printers
Res = RegOpenKeyEx(HKCU, PRINTER_KEY, 0&, _
    KEY_QUERY_VALUE, HKey)
' start enumeration loop of printers
Res = RegEnumValue(HKey, Ndx, ValueName, _
    ValueNameLen, 0&, DataType, ValueValue(0), 1000)
' loop until all values have been enumerated
Do Until Res = ERROR_NO_MORE_ITEMS
    M = InStr(1, ValueName, Chr(0))
    If M > 1 Then
        ' clean up the ValueName
        ValueName = Left(ValueName, M - 1)
    End If
    ' find position of a comma and colon in the port name
    CommaPos = InStr(1, ValueValue, ",")
    ColonPos = InStr(1, ValueValue, ":")
    ' ValueValue byte array to ValueValueS string
    On Error Resume Next
    ValueValueS = Mid(ValueValue, CommaPos + 1, ColonPos - CommaPos)
    On Error GoTo 0
    ' next slot in Printers
    PNdx = PNdx + 1
    Printers(PNdx) = ValueName & " on " & ValueValueS
    ' reset some variables
    ValueName = String(255, Chr(0))
    ValueNameLen = 255
    ReDim ValueValue(0 To 999)
    ValueValueS = vbNullString
    ' tell RegEnumValue to get the next registry value
    Ndx = Ndx + 1
    ' get the next printer
    Res = RegEnumValue(HKey, Ndx, ValueName, ValueNameLen, _
        0&, DataType, ValueValue(0), 1000)
    ' test for error
    If (Res <> 0) And (Res <> ERROR_MORE_DATA) Then
        Exit Do
    End If
Loop
' shrink Printers down to used size
ReDim Preserve Printers(1 To PNdx)
Res = RegCloseKey(HKey)
' Return the result array
GetPrinterFullNames = Printers
End Function

Sub Test()
    Dim Printers() As String
    Dim N As Long
    Dim S As String
    Printers = GetPrinterFullNames()
    For N = LBound(Printers) To UBound(Printers)
        S = S & Printers(N) & vbNewLine
    Next N
    MsgBox S, vbOKOnly, "Printers"
End Sub

回答2:

The connection is the first part of the enumeration. Essentially .Item(i + 1) & " on ' & .Item(i). In your code this would be,

fullName = nwo.EnumPrinterConnections(i * 2 + 1) & " on " & nwo.EnumPrinterConnections(i * 2)

You will have to fill a list of the similar printers; currently, you are only returning the last match.

来源：https://stackoverflow.com/questions/31575572/trouble-listing-printers-with-excel-vba

标签

vba

excel

printing