Using a dynamically generated variable name in Perl's strict mode [duplicate]

Question

This question already has an answer here:

• How can I use a variable as a variable name in Perl? 3 answers

Basically, I would like to grab the contents of a variable named in a dynamically generated string, but all efforts to accomplish this in strict mode have failed. There are several posts about similar problems, but none seem to have solutions that have worked for me.

This is what I want to do:

# Fields:
$q1 = "ex. data 1";
$q2 = "ex. data 2";
$q3 = "ex. data 3";
$q4 = "ex. data 4";
$q5 = "ex. data 5";

# retrieve the desired field name.  q1, q2, q3, q4, or q5.
$field_name = fetch_the_desired_field_name();

# fetch the contents of the named field.  ex. data 1, ex. data 2, etc.
$contents_of_desired_field = $$field_name;

print $contents_of_desired_field;

Is there a way to do this in strict mode? In other posts about similar problems, people say that hashes are the answer, but I can't seem to quite grasp how to do this with a hash. It goes without saying that this is a very simplified example. In the actual code, there are 115 possible field names, all pulled from a database, with unpredictable contents.

Answer 1

To do this with a hash:

Store:

$myHash{q3} = "ex. data 3";

Retrieve:

$result = $myHash{q3};

This has multiple benefits such as:

• Satisfies "use strict";

• You can loop over all the field names via keys %myHash

• Since the field names are a list as per the last point, you can do any other list operations on them if needed (map, grep) etc...

  • For example, to get only the values where field name is of a form "q[1-5]", you can do:

    @subset = @myHash{ grep m/q[1-5]/ keys %myHash }; # Use a slice @{} operator.
    

  • Most database APIs (e.g. DBI) have calls which will automatically return back this exact format of a hash (or rather a hash reference instead) when querying a row from a table

    $hash_ref = $sth->fetchrow_hashref;
    

Answer 2

You don't want to dynamically generate variable names! Instead, use a hash or an array:

my @q = ("ex. data 1", ..., "ex. data 5");

my $contents  = $q[ $some_index ];

print $contents;

Where $some_index is set to the desired index, thus removing any need for dynamic names.

Answer 3

strict explicitly does not allow you to use what are called "symbolic references". You can get around this by asking Perl for permission:

use strict;
use warnings;
use 5.10.0;

our $x = '5';
my $field_name = 'x';

my $contents;
{ # no strict is lexially scoped
    no strict 'refs';
    $contents = ${$field_name};
}

say $contents;

Note that the referenced variable has to be dynamic, not lexical, and that this practice is generally discouraged. Here's how you solve your problem with hashes, the correct data type:

# Fields:
my %data = (
    q1 => "ex. data 1",
    q2 => "ex. data 2",
    q3 => "ex. data 3",
    q4 => "ex. data 4",
    q5 => "ex. data 5",
);

# retrieve the desired field name.  q1, q2, q3, q4, or q5.
$field_name = fetch_the_desired_field_name();

# fetch the contents of the named field.  ex. data 1, ex. data 2, etc.
$contents_of_desired_field = $data{$field_name};

print $contents_of_desired_field;

There. No messy no strict, just one variable holding all your data.