Android Studio - Could not find org.jetbrains.kotlin:kotlin-stdlib:1.1.3-2

问题

I was tring to compile my project in Android Studio (using Java) and the following error appeared:

Could not find org.jetbrains.kotlin:kotlin-stdlib:1.1.3-2.
Searched in the following locations:
  - https://maven.fabric.io/public/org/jetbrains/kotlin/kotlin-stdlib/1.1.3-2/kotlin-stdlib-1.1.3-2.pom
  - https://maven.fabric.io/public/org/jetbrains/kotlin/kotlin-stdlib/1.1.3-2/kotlin-stdlib-1.1.3-2.jar
  - https://dl.google.com/dl/android/maven2/org/jetbrains/kotlin/kotlin-stdlib/1.1.3-2/kotlin-stdlib-1.1.3-2.pom
  - https://dl.google.com/dl/android/maven2/org/jetbrains/kotlin/kotlin-stdlib/1.1.3-2/kotlin-stdlib-1.1.3-2.jar

Since I am not using kotlin I do not understand why is it being requested to compile my project.

The rest of questions I've seen about it here are about Kotlin projects or missing SDK but it is not my case.

build.gradle (app):

buildscript {
    repositories {
        maven { url 'https://maven.fabric.io/public' }
        google()
    }

    dependencies {
        classpath 'io.fabric.tools:gradle:1.27.1'
        classpath 'com.android.tools.build:gradle:3.0.0'
    }
}
apply plugin: 'com.android.application'
apply plugin: 'io.fabric'

repositories {
    maven { url 'https://maven.fabric.io/public' }
}


android {
    compileSdkVersion 27
    defaultConfig {
        applicationId "com.project.test"
        minSdkVersion 22
        targetSdkVersion 27
        versionCode 10
        versionName "0.19"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'),     'proguard-rules.pro'
        }
    }
    dataBinding.enabled = true
    testOptions {
        unitTests.all {
            jvmArgs '-XX:MaxPermSize=256m'
        }
        unitTests.returnDefaultValues = true
    }
    packagingOptions {
        exclude 'META-INF/proguard/androidx-annotations.pro'
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation 'com.android.support:appcompat-v7:27.1.1'
    testImplementation 'junit:junit:4.12'
    testImplementation 'org.json:json:20180130'
    androidTestImplementation 'com.android.support.test:runner:1.0.2'
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'
    implementation 'com.android.support:design:27.1.1'
    implementation 'com.squareup.okhttp3:okhttp:3.10.0'
    implementation 'com.github.paolorotolo:expandableheightlistview:1.0.0'
    implementation 'com.google.code.gson:gson:2.8.5'
    def room_version = "1.1.1"

    implementation "android.arch.persistence.room:runtime:$room_version"
    annotationProcessor "android.arch.persistence.room:compiler:$room_version"
    // optional - RxJava support for Room
    implementation "android.arch.persistence.room:rxjava2:$room_version"
    // optional - Guava support for Room, including Optional and ListenableFuture
    //implementation "android.arch.persistence.room:guava:$room_version"

    // Converter
    implementation "android.arch.persistence.room:runtime:1.1.1"
    annotationProcessor "android.arch.persistence.room:compiler:1.1.1"
    implementation 'com.google.code.gson:gson:2.8.5'

    implementation 'com.github.PhilJay:MPAndroidChart:v3.0.2'

    testImplementation "org.powermock:powermock-module-junit4:1.7.4"
    testImplementation "org.powermock:powermock-api-mockito2:1.7.4"

    // WorkManager
    implementation "android.arch.work:work-runtime:1.0.0-beta02"

    // Power menu
    implementation "com.github.skydoves:powermenu:2.0.5"

    // Crashlytics
    implementation('com.crashlytics.sdk.android:crashlytics:2.9.5@aar') {
        transitive = true
    }
}

build.gradle (project):

buildscript {

    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.0.0'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}
allprojects {
    repositories {
        google()
        jcenter()
        maven { url "https://jitpack.io" }
    }
}
task clean(type: Delete) {
    delete rootProject.buildDir
}

dependencies {
}

Thank you in advance.

回答1:

Remove the buildscript block from your app module build.gradle. It overrides whatever the top-level build.gradle provided and it's missing jcenter repo where Kotlin is.

回答2:

So, I found the solution. I was still doing some research and I found this question: possible solution

People said jcenter() must be included in the project-level build.gradle, and since I already had it, I tried to add it to build.gradle (app).

It worked.

If someone could explain why, it would be awesome.

来源：https://stackoverflow.com/questions/54645936/android-studio-could-not-find-org-jetbrains-kotlinkotlin-stdlib1-1-3-2