问题
I found a way to export a hierarchical ALV like this: ABAP: Report via GUI has 18 columns, via RFC 6 (hierarchical ALV)
Unfortunately I don't know in advanced if the report uses hierarchical ALV or not.
If I apply the code of above answer to the report RFSKPL00, then I get an exception in cl_salv_bs_runtime_info=>get_data() here:
if t_data_line is requested.
import t_data_line to t_data_line from memory id cl_salv_bs_runtime_info=>c_memid_data_line.
if sy-subrc ne 0.
raise exception type cx_salv_bs_sc_runtime_info <=========
exporting
textid = 'ERROR'.
endif.
endif.
How can I check (via abap code) if a report uses hierarchical ALV or not?
回答1:
I wanted the same information and the answer by Sandra didn't help me/didn't work, because the parameters just wouldn't fill. But cl_salv_bs_runtime_info has another function that solved my problem, get_metadata. It has a parameter is_hierseq that gets filled as expected.
DATA: runtime_metadata TYPE cl_salv_bs_runtime_info=>s_type_metadata,
lr_data_descr TYPE REF TO cl_abap_datadescr,
lr_data_line_descr TYPE REF TO cl_abap_datadescr,
lr_data TYPE REF TO data,
lr_data_line TYPE REF TO data.
FIELD-SYMBOLS: <lt_data> TYPE ANY TABLE,
<lt_data_line> TYPE ANY TABLE.
------------------------------------------------------------------------------
" initialising runtime analysis
cl_salv_bs_runtime_info=>set( EXPORTING display = abap_false
metadata = abap_true
data = abap_true ).
***** Calling reports in different ways:
*** calling using SUBMIT:
* ALV grid output:
*SUBMIT bcalv_grid_07 AND RETURN.
* hierarchical output:
*SUBMIT SALV_DEMO_HIERSEQ_SIMPLE AND RETURN.
*** calling using CALL TRANSACTION:
* ALV grid / hierarchical output:
CALL TRANSACTION 'MB51'.
* Testing output mode using metadata
runtime_metadata = cl_salv_bs_runtime_info=>get_metadata( ).
IF runtime_metadata-is_hierseq IS INITIAL.
* ALV Grid / SALV
cl_salv_bs_runtime_info=>get_data_ref( IMPORTING
r_data_descr = lr_data_descr ).
CREATE DATA lr_data TYPE HANDLE lr_data_descr.
ASSIGN lr_data->* TO <lt_data>.
cl_salv_bs_runtime_info=>get_data( IMPORTING
t_data = <lt_data> ).
ELSE.
* hierarchical
cl_salv_bs_runtime_info=>get_data_ref(IMPORTING
r_data_descr = lr_data_descr
r_data_line_descr = lr_data_line_descr).
CREATE DATA lr_data TYPE HANDLE lr_data_descr.
CREATE DATA lr_data_line TYPE HANDLE lr_data_line_descr.
ASSIGN lr_data->* TO <lt_data>.
ASSIGN lr_data_line->* TO <lt_data_line>.
cl_salv_bs_runtime_info=>get_data( IMPORTING
t_data = <lt_data>
t_data_line = <lt_data_line> ).
ENDIF.
In the case of an ALV/SALV, <lt_data> will contain the output, in the case of a hierarchical list it will be <lt_data_line> instead.
回答2:
You can use TRY / CATCH / ENDTRY to prevent dumps based on catchable class based exceptions:
DATA lx_runtime_info TYPE REF TO cx_salv_bs_sc_runtime_info.
TRY.
cl_salv_bs_runtime_info=>get_data(
IMPORTING
t_data = <lt_data>
t_data_line = <lt_data_line>
).
CATCH cx_salv_bs_sc_runtime_info INTO lx_runtime_info.
DATA(lv_result) = lx_runtime_info->if_message~get_text( ).
DATA(lv_result_long) = lx_runtime_info->if_message~get_longtext( ).
ENDTRY.
(ST22 will always tell you which exception class you have to use.)
As all exception classes are subclasses (sub-subclasses, sub-sub-subclasses, etc.) of CX_ROOT, so you can use the methods get_text and get_longtext to get more information (implemented through interface if_message) about the problem.
回答3:
To determine whether the ALV is a classic ALV or a hierarchical-sequential list :
IF cl_salv_bs_runtime_info=>get( )-structure_line IS INITIAL.
"---------------------
" classic ALV
"---------------------
cl_salv_bs_runtime_info=>get_data_ref(
IMPORTING r_data = DATA(lr_data) ).
ELSE.
"---------------------
" hierarchical-sequential list
"---------------------
cl_salv_bs_runtime_info=>get_data_ref(
IMPORTING r_data = lr_data
r_data_line = DATA(lr_data_line) ).
ENDIF.
来源：https://stackoverflow.com/questions/53172303/check-if-report-uses-hierarchical-alv-or-not