Delphi - Get the whole word where the caret is in a memo

问题

I need to be able to select the whole word of a TMemo if the caret is directly adjacent or in a word in the memo.

Consider the following (where | is a caret)

Here is some text| = Select text

Here is so|me text = Select some

|Here is some text = Select Here

Here is some text | = Select ''

回答1:

Check this code with comments to explain how works.

function SelectWordUnderCaret(AMemo:TMemo):string;
var
   Line    : Integer;
   Column  : Integer;
   LineText: string;
   InitPos : Integer;
   EndPos  : Integer;
begin
   //Get the caret position
   Line   := AMemo.Perform(EM_LINEFROMCHAR,AMemo.SelStart, 0) ;
   Column := AMemo.SelStart - AMemo.Perform(EM_LINEINDEX, Line, 0) ;
   //Validate the line number
   if AMemo.Lines.Count-1 < Line then Exit;

   //Get the text of the line
   LineText := AMemo.Lines[Line];

   Inc(Column);
   InitPos := Column;
   //search the initial position using the space symbol as separator
   while (InitPos > 0) and (LineText[InitPos] <> ' ') do Dec(InitPos);
   Inc(Column);

   EndPos := Column;
   //search the final position using the space symbol as separator
   while (EndPos <= Length(LineText)) and (LineText[EndPos] <> ' ') do Inc(EndPos);

   //Get the text
   Result := Trim(Copy(LineText, InitPos, EndPos - InitPos));

   //Finally select the text in the Memo
   AMemo.SelStart  := AMemo.Perform(EM_LINEINDEX, Line, 0)+InitPos;
   AMemo.SelLength := Length(Result);
end;

and you can use like this

procedure TForm1.Button1Click(Sender: TObject);
begin
     Caption := SelectWordUnderCaret(Memo1) ;
end;

来源：https://stackoverflow.com/questions/6339446/delphi-get-the-whole-word-where-the-caret-is-in-a-memo