问题

I heard that java code cannot be to add into batch file in a comment on my previous question:

But is there any alternatives to it?
Is it possible to add java code into batch file?

I tried the following in the batch file but it does not work:

vol231.exe -f m.walkin(new File(d.detectDrive())) imageinfo > Volatility.txt

This is cmdenv.bat that i created to run in command prompt from java:

E:
echo off
cls

... //This part is a long part for reducing footprint whereby the command prompt is switched to Helix

vol231.exe -f E:\KOHMOHOJOJO-PC-20140714-152414.raw imageinfo > Volatility.txt
vol231.exe -f E:\KOHMOHOJOJO-PC-20140714-152414.raw --profile=Win7SP0x86 pslist >> Volatility.txt
pause
exit

This allows my volatility commands to run in a enclosed command prompt (Helix) which reduces footprint.

However, the volatility commands are all hardcoded. The E:\KOHMOHOJOJO-PC-20140714-152414.raw and --profile=Win7SP0x86 varies. Is there any alternative to do it since batch file does allow java coding?

I am new to java and batch file.

Edit1:

I tried changing the java_path but it still have errors.

Edit2: I tried different paths like:

C:\Program Files\Java\jdk1.8.0_05\bin and C:\Program Files\Java\jre8\bin I get Error: Could not find or load main class TestRun1.
C:\Users\User\workspace\Volatility\bin and C:\Users\User\workspace\Volatility\src (this is the workspace where the class is saved) I get C:\Users\User\workspace\Volatility\(bin or src)\java is not recognised as an internal or external command, operable program or batch file. So I added java.exe into the file. And the error gets back to Error: Could not find or load main class TestRun1.

This batch file doesn't seem to be able to read the java.. I tried adding a . in front of the TestRun1 but still it has the same error. I also found out that I have the environment variable under Control Panel\System and Security\System\Advance System Settings\Environment Variables (Path). I tried deleting C:\Program Files\Java\jdk1.8.0_05\bin and then running it but it still has the same error.

回答1:

So it is possible to add java code into batch file?

No, you cannot add Java code to batch file.

Alternative Workaround:

To use Java value in batch file, print the value in Java, Use that value in batch file.

In Java,

public class TestRun1
{
    public static void main(String args[])
    {
       System.out.println(m.walkin(new File(d.detectDrive())));
    }
}

In batch file:

set tmp_file=%TEMP%\%~n0.tmp

rem ----set as per your java directory-------
set java_path=C:\Program Files\Java\jdk1.6.0_43\bin

"%java_path%\java" TestRun1> "%tmp_file%"
set /P p=<"%tmp_file%"
echo %p%

rem -----now p has the value, use it in the command--------

vol231.exe -f %p% imageinfo > Volatility.txt
vol231.exe -f %p% --profile=Win7SP0x86 pslist >> Volatility.txt
vol231.exe -f %p% --profile=Win7SP0x86 dlllist > Volatility.txt
vol231.exe -f %p% --profile=Win7SP0x86 iehistory >> Volatility.txt
vol231.exe -f %p% --profile=Win7SP0x86 svcscan >> Volatility.txt
vol231.exe -f %p% --profile=Win7SP0x86 hivelist >> Volatility.txt
vol231.exe -f %p% --profile=Win7SP0x86 filescan >> Volatility.txt
vol231.exe -f %p% --profile=Win7SP0x86 netscan >> Volatility.txt
pause
del /F "%tmp_file%"

回答2:

Make your Java program pass the filename to the batch file as a command-line option. Within the batch file, you can access the it as the variable %1. You can pass multiple command-line options; the others will be available as %2, %3, and so on.

回答3:

Here how you can add java code to batch file (though it's not exactly complete solution for your problem):

 @Deprecated /* >nul 2>&1

:: self compiled java/.bat hybrid
::
:: deprecated is the only one annotation that can be used outside the class definition
:: and is needed for 'mute' start of multi-line java comment
:: that will be not printed by the batch file.
:: though it still created two files - the .class and the .java
:: it still allows you to embed both batch and java code into one file

@echo off
setlocal
java -version >nul 2>&1 || (
    echo java not found
    exit /b 1
)

::find class name
for /f "usebackq tokens=3 delims=} " %%c in (`type %~f0 ^|find /i "public class"^|findstr /v "for /f"`) do (
    set "javaFile=%%c"
    goto :skip
)
:skip

copy "%~f0" "%javaFile%.java" >nul 2>&1

javac "%javaFile%.java" 
java "%javaFile%"

::optional
::del %javaFile%.* >nul 2>&1 
end local
exit /b 0

*******/



public class TestClass
{
    public static void main(String args[])
    {
       System.out.println("selfcompiled .bat/.java hybrid");
    }
}

Deprecated annotation is the only one I've found that can be set outside the class.And annotation is needed to avoid toxic output.It also creates two temporary files (.class and .java) which you can delete.

来源：https://stackoverflow.com/questions/24752040/alternatives-to-batch-file-since-i-am-unable-to-include-java-code-in-it

标签

java