Using scanf into global or local variables (on the stack), 32-bit calling convention

问题

Given the following code :

    .section    .rodata
str:    .string "Hello World!\n"
input:  .long 2
    ########
    .text
.globl  main
    .type main, @function
main:
    pushl   %ebp
    movl    %esp,   %ebp

    pushl   $str
    call    printf

    #return from printf:
    movl    $0, %eax
    movl    %ebp,%esp
    popl    %ebp
    ret

The output would be "Hello World!".

---

Now I try to get a number from the user , and then print it out on the screen , but it doesn't work (code compile,but I did something wrong) . Where is my mistake ?

    .section    .rodata
input:  .long   2
    ########
    .text
.globl  main
    .type main, @function
main:
    pushl   %ebp
    movl    %esp,   %ebp
    pushl   %ebx    

    call    scanf  # call scanf to get number from the user
    popl    input  # store the number entered by user in input (variable)
    pushl   input  # push it back into the stack
    call    printf # print input

    #return from printf:
    movl    $0, %eax
    movl    %ebp,%esp
    popl    %ebp
    ret

回答1:

I'm not really sure what sort of assembler you're using, however I could get your code to compile with gcc so I stuck with your formatting style (not talking about the AT&T syntax).

Anyway, you should check the documentation for scanf and realise that it takes a format string and pointers to locations in memory of where to store the values read in. It also returns the number of successfully read items and not what was read.

Now do the same and check the documention for printf. You'll see that a format string is required to print your number in a readable form. A suitable format string is "%d\n" to print the number and a newline.

Your code could now look something like this (which compiles and works fine for me with gcc):

.section .rodata

input_format:  .string  "%d"
output_format: .string  "%d\n"

.section .bss
input:  .long  0          # reserve 4 bytes of space

.section .text
.globl  main
    .type main, @function
main:
    pushl   %ebp
    movl    %esp,   %ebp

    pushl   $input    # push the ADDRESS of input to have the value stored in it
    pushl   $input_format   # give scanf the ADDRESS of the format string
    call    scanf    # call scanf to get number from the user
    addl    $8, %esp # clean up the stack
    
    # Note the return value of scanf is passed through eax (same for printf)
    
    pushl   input    # pass the number to printf BY VALUE
    pushl   $output_format  # pass the ADDRESSS of the output format string to printf
    call    printf   # print input

    #return 0 from main:
    movl    $0, %eax
    movl    %ebp,%esp
    popl    %ebp
    ret

Note that I would normally use db/dw/dd for allocating memory in the .(ro)data and .bss sections as opposed to .string and .long, so if that part's done slightly wrong you could just fix it up.

You could also use stack space for storing the number, however you already had input declared and I wanted to leave the code as similar to what you had as possible. Same goes for everything else before and after the scanf and printf stuff, I just left that as your code.

EDIT: Here's an example of using the stack to create a local variable, as opposed to having a variable declared in the .bss or .data segment:

.section .rodata

input_format:  .string  "%d"
output_format: .string  "%d\n"

.section .text
.globl  main
    .type main, @function
main:
    pushl   %ebp
    movl    %esp,   %ebp

    subl    $4, %esp       # allocate 4 bytes on the stack for a local variable

    # The local variable will be at -4(%ebp)

    leal    -4(%ebp), %eax # get the ADDRESS of our local variable
    pushl    %eax          # push the ADDRESS of the variable on the stack
    pushl   $input_format  # give scanf the ADDRESS of the format string
    call    scanf          # call scanf to get number from the user
    addl    $8, %esp       # clean up the stack

    # Note the return value of scanf is passed through eax (same for printf)

    pushl   -4(%ebp)       # pass the number to printf BY VALUE
    pushl   $output_format # pass the ADDRESSS of the output format string to printf
    call    printf         # print the input

    #return from printf:
    movl    $0, %eax
    movl    %ebp,%esp
    popl    %ebp
    ret

回答2:

Your arguments to scanf are incorrect, you need to push both a scan format and buffers to hold the types that you are looking for, then, if they aren't strings, you need to push a new formatting string to printf, in this case "%d".

it would look a little like this (sorry its in Intel/MASM format):

SUB ESP,4 ;make stack space for an int
LEA EAX,[ESP]
PUSH EAX
PUSH offset NumberString ;"%d"
CALL scanf
PUSH [ESP+8] ;our scanned number
PUSH offset NumberString ;"%d"
CALL printf
ADD ESP,20 ;clean up for the cdecl funcs and the alloc'ed stack space

来源：https://stackoverflow.com/questions/8529810/using-scanf-into-global-or-local-variables-on-the-stack-32-bit-calling-conven