xml transform to html using xslt

问题

I'm trying to use key function to transform xml to html look like:

but I don't know how to make two table, because my if function write books one under other. A XML looks like:

<library>
<books>
    <book aut="JKR">
        <title>Harry Potter and the Sorcerer's Stone</title>
        <quantity>5</quantity>
    </book>
</books>
<books>
    <book aut="JKR">
        <title>example</title>
        <quantity>3</quantity>
    </book>
    <book aut="AC">
        <title>example</title>
        <quantity>2</quantity>
</books>
<authors>
    <author id="JKR">J.K.Rowling</author>
    <author id="AC"> Agatha Christie</author>
<authors>

And is fragment xslt code:

  <?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" indent="yes" doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN" />
    <xsl:output method="html"  encoding="iso-8859-2" />
    <xsl:key name="idauthor" match="author" use="@id"/>
    <xsl:template match="/">
        <html>
            <head>
                <meta content="text/html" />
                       </head>
     <body>

      <table border="1">
            <xsl:apply-templates select="//book"/>
      </table>

    </body>
  </html>
</xsl:template>

<xsl:template match="book">


   <xsl:if test="key('idauthor',@author)">

      <tr>   author:
            <td> <xsl:value-of select="title" /></td>
            <td> <xsl:value-of select="quantity" /></td>
      </tr>
     </xsl:if >
  </xsl:template>   
</xsl:stylesheet>

回答1:

If your input has an authors index, and you want to report by author, then you should start with that.

<xsl:apply-templates select="authors/author"/>

You then want to apply the key to books, not authors:

<xsl:key name="books-by" match="book" use="@aut"/>

Finally, for each author, you want to select the books by the author's id:

<table border="1">
    <xsl:apply-templates select="key('books-by', @id)" />
</table>

The following transform

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
                                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" indent="yes" doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN" />
    <xsl:output method="html"    encoding="iso-8859-2" />
    <xsl:key name="books-by" match="book" use="@aut"/>

    <xsl:template match="/library">
        <html>
            <head>
                <meta content="text/html" />
            </head>
            <body>
                <xsl:apply-templates select="authors/author"/>
            </body>
        </html>
    </xsl:template>

    <xsl:template match="author">
        <h2>
            <xsl:value-of select="."/>
        </h2>
        <table border="1">
            <xsl:apply-templates select="key('books-by', @id)" />
        </table>

    </xsl:template>

    <xsl:template match="book">
        <tr>
            <td> <xsl:value-of select="position()" /></td>
            <td> <xsl:value-of select="title" /></td>
            <td> <xsl:value-of select="quantity" /></td>
        </tr>
    </xsl:template>     
</xsl:stylesheet>

applied to your (corrected) input,

<library>
    <books>
        <book aut="JKR">
            <title>Harry Potter and the Sorcerer's Stone</title>
            <quantity>5</quantity>
        </book>
    </books>
    <books>
        <book aut="JKR">
            <title>example</title>
            <quantity>3</quantity>
        </book>
        <book aut="AC">
            <title>example</title>
            <quantity>2</quantity>
        </book>
    </books>
    <authors>
        <author id="JKR">J.K.Rowling</author>
        <author id="AC"> Agatha Christie</author>
    </authors>
</library>

produces the following HTML:

<!DOCTYPE html PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
    <head>
        <META http-equiv="Content-Type" content="text/html; charset=utf-8">
        <meta content="text/html">
    </head>
    <body>
        <h2>J.K.Rowling</h2>
        <table border="1">
            <tr>
                <td>1</td>
                <td>Harry Potter and the Sorcerer's Stone</td>
                <td>5</td>
            </tr>
            <tr>
                <td>2</td>
                <td>example</td>
                <td>3</td>
            </tr>
        </table>
        <h2> Agatha Christie</h2>
        <table border="1">
            <tr>
                <td>1</td>
                <td>example</td>
                <td>2</td>
            </tr>
        </table>
    </body>
</html>

来源：https://stackoverflow.com/questions/23548917/xml-transform-to-html-using-xslt

标签

xml

xslt

idref