SQL Server sp_msforeachtable usage to select only those tables which meet some condition

问题

I am trying to write this query to find all tables with specific column with some specific value. This is what I\'ve done so far -

EXEC sp_MSforeachtable 
@command1=\'
IF EXISTS (SELECT * FROM INFORMATION_SCHEMA.COLUMNS WHERE TABLE_SCHEMA=PARSENAME(\"?\",2) AND TABLE_NAME=PARSENAME(\"?\",1) AND COLUMN_NAME=\"EMP_CODE\")
BEGIN
    IF (SELECT COUNT(*) FROM ? WHERE EMP_CODE=\"HO081\")>0
    BEGIN
        SELECT * FROM ? WHERE EMP_CODE=\"HO081\"
    END
END
\'

I hope my intensions are clear, I just want to select only those tables where the column EMP_CODE is present and in those tables I want to select those rows where EMP_CODE=\'HO081\'.

Edit -

Now it stands like this. But I\'m not able to replace @EMPCODE variable in the query.

DECLARE @EMPCODE AS VARCHAR(20)
SET @EMPCODE=\'HO081\'
EXEC sp_MSforeachtable 
@command1=\'
    DECLARE @COUNT AS INT
    SELECT @COUNT=COUNT(*) FROM ? WHERE EMP_CODE=\'\'\'+@EMPCODE+\'\'\'
    IF @COUNT>0
    BEGIN
        PRINT PARSENAME(\"?\",1)+\'\' => \'\'+CONVERT(VARCHAR,@COUNT)+\'\' ROW(S)\'\'
        --PRINT \'\'DELETE FROM \'\'+PARSENAME(\"?\",1)+\'\' WHERE EMP_CODE=\'\'\'\'\'+@EMPCODE+\'\'\'\'\'\'\'
    END
\',@whereand=\'AND O.ID IN (SELECT OBJECT_ID FROM SYS.COLUMNS C WHERE C.NAME=\'\'\'+@EMPCODE+\'\'\')\'

回答1:

You know how sp_MSforeachtable is undocumented, and may go away at any time/be modified?

Well, if you're happy to ignore that, it has another parameter called @whereand, which is appended to the WHERE clause of the internal query that is being used to find the tables (and should start with an AND).

You also have to know that there's an alias, o against sysobjects, and a second alias syso against sys.all_objects.

Using this knowledge, you might craft your @whereand parameter as:

EXEC sp_MSforeachtable 
@command1='...',
@whereand='AND o.id in (select object_id from sys.columns c where c.name=''EMP_CODE'')'

You can now also simplify your command1, since you know it will only be run against tables containing an EMP_CODE column. I'd probably take out the COUNT(*) condition also, since I don't see what value it's adding.

---

Updated based on your further work, and tested against one table:

DECLARE @EMPCODE AS VARCHAR(20)
SET @EMPCODE='HO081'
declare @sql nvarchar(2000)
set @sql = '
    DECLARE @COUNT AS INT
    SELECT @COUNT=COUNT(*) FROM ? WHERE EMP_CODE='''+@EMPCODE+'''
    IF @COUNT>0
    BEGIN
        PRINT PARSENAME("?",1)+'' => ''+CONVERT(VARCHAR,@COUNT)+'' ROW(S)''
        --PRINT ''DELETE FROM ''+PARSENAME("?",1)+'' WHERE EMP_CODE='''''+@EMPCODE+'''''''
    END
'
EXEC sp_MSforeachtable 
@command1=@sql,@whereand='AND O.ID IN (SELECT OBJECT_ID FROM SYS.COLUMNS C WHERE C.NAME=''EMP_CODE'')'

(I've reverted the @whereand to query for EMP_CODE, since you don't want to replace the value there).

The issue is that, you can pass parameters to a stored procedure, or literals, but you can't perform calculations/combining actions between them - so I moved the construction of the sql statement out into a separate action.

回答2:

I guess you get an error of some kind, perhaps Invalid column name 'EMP_CODE'?

It's because the code is compiled before you check for the column. You could do like this instead.

EXEC sp_MSforeachtable 
@command1='
IF EXISTS (SELECT * FROM INFORMATION_SCHEMA.COLUMNS WHERE TABLE_SCHEMA=PARSENAME("?",2) AND TABLE_NAME=PARSENAME("?",1) AND COLUMN_NAME="EMP_CODE")
BEGIN
   EXEC(''
          IF (SELECT COUNT(*) FROM ? WHERE EMP_CODE="HO081")>0
          BEGIN
              SELECT * FROM ? WHERE EMP_CODE="HO081"
          END
        '')
END
'

来源：https://stackoverflow.com/questions/9679997/sql-server-sp-msforeachtable-usage-to-select-only-those-tables-which-meet-some-c