Unresolved reference: compileKotlin in build.gradle.kts

问题

Kotlin project success build by build.gradle:

compileKotlin {
    kotlinOptions.jvmTarget = JavaVersion.VERSION_1_8
}
compileTestKotlin {
    kotlinOptions.jvmTarget = JavaVersion.VERSION_1_8
}

Nice.

But I need to change to build.gradle.kts:

 plugins {
    kotlin("jvm") version "1.2.10"
    id("application")
}

group = "com.myproject"
version = "1.0-SNAPSHOT"

application {
    mainClassName = "MainKt"
}

java.sourceCompatibility = JavaVersion.VERSION_1_8

repositories {
    mavenCentral()
    jcenter()
}

val kotlinVer = "1.2.10"

dependencies {
    compile(kotlin(module = "stdlib-jre8", version = kotlinVer))
    implementation("com.google.code.gson:gson:2.7")
    implementation("com.squareup.okhttp3:logging-interceptor:3.8.0")
    implementation("com.squareup.retrofit2:converter-gson:2.1.0")
    implementation("com.squareup.retrofit2:retrofit:2.5.0")
    implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk8")

}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}
compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

and now I get error:

Line 32: compileKotlin {
           ^ Unresolved reference: compileKotlin

回答1:

There's an issue in the Kotlin Gradle DSL that causes this.

https://github.com/gradle/kotlin-dsl-samples/issues/1368

You will need to use the following workaround until it gets resolved.

tasks.withType<KotlinCompile> {
    kotlinOptions {
        jvmTarget = "1.8"
    }
}

回答2:

Following official Kotlin documentation (using Gradle part), I suggest to use such constructions in the build.gradle.kts:

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    java
    kotlin("jvm") version ("1.3.21")
}
// repositories, dependencies, etc...
val compileKotlin: KotlinCompile by tasks
val compileTestKotlin: KotlinCompile by tasks

compileKotlin.kotlinOptions {
    jvmTarget = "1.8"
}
compileTestKotlin.kotlinOptions {
    jvmTarget = "1.8"
}

回答3:

Use withType keyword:

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    val kotlin = "1.3.61"
    kotlin("jvm") version kotlin apply false
}

subprojects {
    repositories { mavenCentral(); mavenLocal() }
    apply(plugin = "org.jetbrains.kotlin.jvm")

    tasks {
        val java: String by project
        withType<KotlinCompile>{ 
            kotlinOptions { jvmTarget = java }; sourceCompatibility = java; targetCompatibility = java 
        }
    }
}

来源：https://stackoverflow.com/questions/55456176/unresolved-reference-compilekotlin-in-build-gradle-kts

标签

gradle

kotlin

gradle-kotlin-dsl