小爱同学脱离局域网远程控制开关？

小爱同学脱离局域网远程控制开关？

这是几个月前做的一个小项目，也是从大佬那里学来的，为了防止忘记过程，自己做个记录，同时分享给需要的人

这个项目需要用到的东西有：电脑端Arduino IDE，小米手机小爱同学，手机APP点灯·blinker，esp8266nodemcu，以及杜邦线面包板小灯

1、Arduino IDE根据自己的系统安装合适的版本我目前用的是1.8.9版本

安装esp8266拓展，这里点灯科技提供了资源，需要的小伙伴去找官方开发文档

以及下载安装blinker-Arduino库：
方法一：打开软件IDE，在项目–》加载库–》管理库下搜索blinker进行安装在这里插入图片描述
安装最新版本

方法二：找到点灯科技官方开发文档，快速入门esp8266WiFi接入
在这里插入图片描述
点击下载，根据要求安装

到目前为止，电脑端的配置就完成了

2、手机APP点灯下载
在这里插入图片描述
这样获取到secret Key，到时候代码里要用到

3、打开IDE 新建文件输入代码

#define BLINKER_WIFI
#define BLINKER_MIOT_MULTI_OUTLET    //设置为小爱多个插座的模式

#include <Blinker.h>
BlinkerButton Button1("btn-km");     //设置blinkerapp内数据键名
BlinkerButton Button2("btn-kckm");   //这里只用了其中三个
BlinkerButton Button3("btn-gckm");  
BlinkerText Text1("text_1");


char i;

char auth[] = "密钥(secret Key)";
char ssid[] = "WiFi名称";
char pswd[] = "WiFi密码";

bool oState[5] = { false };    //设置5路开关控制

void miotPowerState(const String & state, uint8_t num)     //小爱同学控制指令 
{
    BLINKER_LOG("need set outlet: ", num, ", power state: ", state);   
    if(num==1){
      i=D1;          //指定每一路开关对应在开发板上的通道接口
    }else if(num==2){
      i=D2;
    }else if(num==3){
      i=D5;
    }

    if (state == BLINKER_CMD_ON) {      
        digitalWrite(i, HIGH);      //这里控制模式都是点动模式 

        BlinkerMIOT.powerState("on", num);
        BlinkerMIOT.print();

        oState[num] = true;
        
    }
    else if (state == BLINKER_CMD_OFF) {
        digitalWrite(i, LOW);

        BlinkerMIOT.powerState("off", num);
        BlinkerMIOT.print();

        oState[num] = false;

        if (num == 0)
        {
            for (uint8_t o_num = 0; o_num < 5; o_num++)
            {
                oState[o_num] = false;
            }
        }
    }
}

void miotQuery(int32_t queryCode, uint8_t num)
{
    BLINKER_LOG("AliGenie Query outlet: ", num,", codes: ", queryCode);

    switch (queryCode)
    {
        case BLINKER_CMD_QUERY_ALL_NUMBER :
            BLINKER_LOG("MIOT Query All");
            BlinkerMIOT.powerState(oState[num] ? "on" : "off", num);
            BlinkerMIOT.print();
            break;
        case BLINKER_CMD_QUERY_POWERSTATE_NUMBER :
            BLINKER_LOG("MIOT Query Power State");
            BlinkerMIOT.powerState(oState[num] ? "on" : "off", num);
            BlinkerMIOT.print();
            break;
        default :
            BlinkerMIOT.powerState(oState[num] ? "on" : "off", num);
            BlinkerMIOT.print();
            break;
    }
}

void dataRead(const String & data)
{
    BLINKER_LOG("Blinker readString: ", data);

    Blinker.vibrate();
    
    uint32_t BlinkerTime = millis();
    
    Blinker.print("millis", BlinkerTime);
}


void button1_callback(const String & state)     //点灯app内控制按键触发
{
    BLINKER_LOG("get button state: ", state);
        digitalWrite(D1, HIGH);
        Blinker.print("开门命令已经处理");
        Text1.print("shuju");
        
}

void button2_callback(const String & state)     //点灯app内控制按键触发
{
    BLINKER_LOG("get button state: ", state);
        digitalWrite(D2, HIGH);

}

void button3_callback(const String & state)     //点灯app内控制按键触发
{
    BLINKER_LOG("get button state: ", state);
        digitalWrite(D5, HIGH);

}


void setup()
{
    Serial.begin(115200);
    BLINKER_DEBUG.stream(Serial);

    pinMode(D1, OUTPUT);
    digitalWrite(D1, LOW);
    pinMode(D2, OUTPUT);
    digitalWrite(D2, LOW);
    pinMode(D5, OUTPUT);
    digitalWrite(D5, LOW);
    

    Blinker.begin(auth, ssid, pswd);
    Blinker.attachData(dataRead);
    
    BlinkerMIOT.attachPowerState(miotPowerState);
    BlinkerMIOT.attachQuery(miotQuery);
    Button1.attach(button1_callback); 
    Button2.attach(button2_callback); 
    Button3.attach(button3_callback); 
}

void loop()
{
    Blinker.run();
}