Photo Mosaic in Mathematica: an example from 2008 doesn't work in Mathematica 8

问题

I'm trying to get a Mathematica example working. It's the one on Theo Gray's blog.

I think that Mathematica must have changed since he wrote that code (May 2008), since I'm unable to get anything reasonable out of it, despite changing nearly everything. Do I use ImageData instead of Import? Can anyone suggest a version of this code that works for Mathematica 8?

imagePool = 
 Map[With[{i = Import[#]}, {i, Mean[Flatten[N[i[[1, 1]]], 1]]}] &, 
  FileNames["Pool/*.jpg"]];
closeMatch[c_] := 
  RandomChoice[Take[SortBy[imagePool, Norm[c - #[[2]]] &], 20]][[1]];
Grid[Reverse[
  Map[closeMatch, Import["MendeleevIcon.tif"][[1, 1]], {2}]], 
  Spacings -> {0, 0}]

回答1:

The following works (Thanks to @yoda for pointing out the Reverse[] thing in the comments):

f = FileNames["*.jpg", {"c:\\test\\pool\\Pool"}];
m = Import["c:\\test\\pool\\Pool\\MendeleevIcon.tif"];
imagePool =
  Map[
   With[{i = Import[#]},
     {i, Mean[Flatten[ImageData@i, 1]]}] &, f];
closeMatch[c_] := 
  RandomChoice[Take[SortBy[imagePool, Norm[c - #[[2]]] &], 20]][[1]];
Grid[Map[closeMatch, ImageData@m, {2}], Spacings -> {0, 0}]

回答2:

Maybe slightly more streamlined:

imagePool = Map[With[{i = Import[#]}, {i, N@Mean[Flatten[ImageData[i], 1]]}] &, 
   FileNames["Pool/*.jpg"]];

closeMatch[c_] := RandomChoice[
   Nearest[imagePool[[All, 2]] -> imagePool[[All, 1]], c, 20]]

ImageAssemble[Map[closeMatch, ImageData[Import["mendeleevIcon.tif"]], {2}]]

Edit

The reason that the original code stopped working in version 8 is that up until version 6 of Mathematica, Import["file.jpg"] would return a Graphics[Raster[]] object. To extract the image data itself you could simply do Import["file.jpg"][[1,1]]. However, in version 8 (and I suspect version 7) raster images are imported as an Image by default which means that you need ImageData to extract the image data from the imported files. You can still import raster images as a Graphics[Raster[]] by using Import["file.jpg","Graphics"] so the original code should still work if you adapt the Import statements, but the advantage of using Image objects is that you can use functions such as ImageAssemble (plus a whole range of other image processing tools that comes with Mathematica 8).

来源：https://stackoverflow.com/questions/7860616/photo-mosaic-in-mathematica-an-example-from-2008-doesnt-work-in-mathematica-8

标签

wolfram-mathematica

backwards-compatibility

mathematica-8