Groovy HTTPBuilder Mocking the Response

问题

I am trying to figure out how to write my Test cases for a service I am going to write.

The service will use HTTPBuilder to request a response from some URL. The HTTPBuilder request only needs to check the response for a success or failure. The service implementation will be be something as simple as:

boolean isOk() {
    httpBuilder.request(GET) {
        response.success = { return true }
        response.failure = { return false }
    }
}

So, I want to be able to mock the HTTPBuilder so that I can set the response to be either success/failure in my test so I can assert that my service's isOk method returns True when the response is a success and False, when the response is a failure.

Can any one help with how I can mock the HTTPBuilder request and set the response in a GroovyTestCase?

回答1:

Here's a minimal example of a mock HttpBuilder that will handle your test case:

class MockHttpBuilder {
    def result
    def requestDelegate = [response: [:]]

    def request(Method method, Closure body) {
        body.delegate = requestDelegate
        body.call()
        if (result)
            requestDelegate.response.success()
        else
            requestDelegate.response.failure()
    }
}

If the result field is true, it'll invoke the success closure, otherwise failure.

EDIT: Here's an example using MockFor instead of a mock class:

import groovy.mock.interceptor.MockFor

def requestDelegate = [response: [:]]
def mock = new MockFor(HttpBuilder)
mock.demand.request { Method method, Closure body ->
    body.delegate = requestDelegate
    body.call()
    requestDelegate.response.success() // or failure depending on what's being tested
}
mock.use {
    assert isOk() == true
}

来源：https://stackoverflow.com/questions/9101084/groovy-httpbuilder-mocking-the-response

标签

unit-testing

groovy

httpbuilder