Why doesn't print output anything on each iteration of a loop when I use sleep?

问题

Today in my college a teacher asked me a question. He wrote this code on the paper and said "What will be the output of this code?"

use warnings;

for (1 .. 20)
{
    print ".";
}

I found it easy and said that it will loop 20 times and at each iteration it will print a dot (.) and hence total 20 dots will be the output.

He said you are right and then he made some changes in the code. The code was:

use warnings;

for (1 .. 20)
{
    print ".";
    sleep 1;
}

He said the what will be the output now? I didn't know about the sleep function, I guessed that at each iteration it will print the dot (.) and then it will wait for 1 second (because of the sleep function) and then again it will iterate and then again it will print (.) then it will wait for 1 second and so on...

The teacher told me to check it at home. I tried it at home and I came to know that the second code waits for 20 seconds and then it prints all dots (20 dots) at once. I want to know how this happened? Why isn't the dot (.) is getting print on each iteration?

回答1:

The real issue has nothing to do with sleep, but rather that............

You are Suffering from Buffering. The link provided takes you to an excellent article from The Perl Journal circa 1998 from Marc Jason Dominus (the author of Higher-Order Perl). The article may be over a decade old, but the topic is as relevant today as it was when he wrote it.

Others have explained the $| = 1; technique. I would add to those comments that in the predominant thinking of the Perl community seems to be that $| = 1 is preferable over $|++ simply because it is clearer in its meaning. I know, autoincrement is pretty simple too, but does everyone who will ever look at your code know $|'s behavior when ++ or -- are applied (without looking it up in perlvar). I happen to also prefer to localize any modification of Perl's "special variables" so that the effects are not washing over into other portions of code that may not play nice with a particular change to default Perl behavior. So that being the case, I would write it as:

use strict;
use warnings;

{
    local $| = 1;
    for ( 1 .. 20 ) {
        print '.';
        sleep 1;
    }
}

回答2:

Perl, and many other programs, line-buffer output by default. You can set $| to 1 if you need unbuffered output.

回答3:

It's not clearing the buffer. If there is a newline at the end of the print statement it will do that for you automatically:

use warnings;

for (1 .. 20) {
    print ".\n";
    sleep 1;
}

If you don't want the newline (I don't imagine you do) you can use the special autoflush variable $|. Try setting it to 1 or incrementing it.

use warnings;

$|++;

for (1 .. 20) {
     print ".";
     sleep 1;
}

来源：https://stackoverflow.com/questions/6558634/why-doesnt-print-output-anything-on-each-iteration-of-a-loop-when-i-use-sleep

标签

perl

buffering