How to get a user by email in JIRA Script Runner

问题

When writing a Groovy script for JIRA Script Runner, how do you get a user, or just their username, given their email address?

It seems that you're supposed to use the findUsersByEmail method in the UserSearchService interface.

https://docs.atlassian.com/jira/7.0.2/com/atlassian/jira/bc/user/search/UserSearchService.html

But how do you get an instance of this class?

Related question: How to get a user by email in a JIRA plugin. The difference is that question is about a plugin, and my question is about JIRA Script Runner.

This code does not work:

setUserProperties(httpMethod: "POST", groups: ["jira-administrators"])
{ MultivaluedMap queryParams, String body, HttpServletRequest request ->

    def userPropertyManager = ComponentAccessor.getUserPropertyManager()
    def userManager = ComponentAccessor.getUserManager()
    def userSearchService = DefaultUserPickerSearchService;
    def users = userSearchService.findUsersByEmail("felicity.smoak@queenconsolidated.com")

    users.each {
        aUser ->
            userPropertyManager.getPropertySet(aUser).setString("jira.meta.Company", "Smoak Technologies")
    }

    return Response.ok(users).build();
}

This is the error I got:

2016-04-18 15:23:06,168 ERROR [common.UserCustomScriptEndpoint]: *************************************************************************************
2016-04-18 15:23:06,168 ERROR [common.UserCustomScriptEndpoint]: Script endpoint failed on method: POST setUserProperties
groovy.lang.MissingMethodException: No signature of method: static com.atlassian.jira.bc.user.search.DefaultUserPickerSearchService.findUsersByEmail() is applicable for argument types: (java.lang.String) values: [felicity.smoak@queenconsolidated.com]
Possible solutions: findUsersByEmail(java.lang.String), findUserKeysByEmail(java.lang.String)
    at Script462$_run_closure3.doCall(Script462.groovy:40)
    at com.onresolve.scriptrunner.runner.rest.common.UserCustomScriptEndpoint.doEndpoint(UserCustomScriptEndpoint.groovy:308)
    at com.onresolve.scriptrunner.runner.rest.common.UserCustomScriptEndpoint.postUserEndpoint(UserCustomScriptEndpoint.groovy:208)

EDIT

Based on @Oldskultxo's and @BjörnKautler suggestions, this is now my working code:

import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.ComponentManager
import com.atlassian.jira.user.*
import com.atlassian.jira.bc.user.search.UserSearchService
import com.atlassian.sal.api.user.UserManager
import com.onresolve.scriptrunner.runner.rest.common.CustomEndpointDelegate
import groovy.json.*
import groovy.transform.BaseScript

import javax.servlet.http.HttpServletRequest
import javax.ws.rs.core.MultivaluedMap
import javax.ws.rs.core.Response

@BaseScript CustomEndpointDelegate delegate

setUserProperties(httpMethod: "POST", groups: ["jira-administrators"])
{ MultivaluedMap queryParams, String body, HttpServletRequest request ->

    def userPropertyManager = ComponentAccessor.getUserPropertyManager()
    def userManager = ComponentAccessor.getUserManager()
    def userSearchService = ComponentAccessor.getComponent(UserSearchService.class)
    def users = userSearchService.findUsersByEmail("felicity.smoak@queenconsolidated.com")

    users.each {
        aUser ->
            userPropertyManager.getPropertySet(aUser).setString("jira.meta.Company", "Smoak Technologies")
    }

    return Response.ok("200").build();
}

回答1:

Use ComponentAccessor.getComponent(UserSearchService) to get the right service if there is no concrete getUserSearchService() method.

回答2:

I usually get components this way:

ComponentManager.getComponentInstanceOfType(UserSearchService.class);

And then just look for its methods.

Regards

来源：https://stackoverflow.com/questions/36698657/how-to-get-a-user-by-email-in-jira-script-runner

标签

groovy

jira

jira-plugin

jira-rest-api