Load different colorscheme when using vimdiff

问题

How to load a different colorscheme when doing vimdiff.

I want this because the my current colorscheme does not show some diffs properly in vimdiff, For. eg some diff is shown with same fg/bg color. This makes it very hard to understand the diff. So every time i do a vimdiff i have to do :colorscheme some_other_scheme

Can this be done in .vimrc file?

回答1:

If you're calling vimdiff from the command-line, put the following in your .vimrc:

if &diff
    colorscheme some_other_scheme
endif

If you're using vimdiff from within vim, you'd either have to override the commands you use to start/stop it (e.g. diffthis, diffoff) using :cnoreabbr (there's also a plugin) or use an autocommand:

au FilterWritePre * if &diff | colorscheme xyz | endif

FilterWritePre is called before filtering through an external program (the diff utility) and the &diff-option is set by vim when it's going into diff-mode (among others, see :help diff)

I'm not sure which autocommand to use to return to the original colorscheme though.

回答2:

I don't know why vim uses so many colors to highlight with, it doesn't really help you figure out what's going on.

I modified my colorscheme to only use one color to highlight (with another to show where theres a difference within a line) and it made all the difference.

Before

After

I did this by adding the following to the end of my colorscheme file (~/.vim/colors/mycolorsheme).

highlight DiffAdd    cterm=bold ctermfg=10 ctermbg=17 gui=none guifg=bg guibg=Red
highlight DiffDelete cterm=bold ctermfg=10 ctermbg=17 gui=none guifg=bg guibg=Red
highlight DiffChange cterm=bold ctermfg=10 ctermbg=17 gui=none guifg=bg guibg=Red
highlight DiffText   cterm=bold ctermfg=10 ctermbg=88 gui=none guifg=bg guibg=Red

cterm - sets the style
ctermfg - set the text color
ctermbg - set the highlighting
DiffAdd - line was added
DiffDelete - line was removed
DiffChange - part of the line was changed (highlights the whole line)
DiffText - the exact part of the line that changed

I used this link as a reference for the color numbers.

Note: I didn't set the gui options because I use a different colorscheme for macvim/gvim

回答3:

To answer my own question:

if &diff
    colorscheme evening
endif

回答4:

I found the easiest way was to paste this one-liner into my ~/.vimrc file:

" Fix the difficult-to-read default setting for diff text highlighting.  The
" bang (!) is required since we are overwriting the DiffText setting. The highlighting
" for "Todo" also looks nice (yellow) if you don't like the "MatchParen" colors.
highlight! link DiffText MatchParen

回答5:

If you are encountering unreadable color schemes (not just ugly, but unreadable like white text on pink background), an easy fix may be to use 16 colors instead of 256 colors. Then you don't have to mess with the color schemes.

The reason is that the default vimdiff color scheme assigns DiffChange bg as "LightMagenta", which gets mapped to a very light pink in 256 colors. That is unreadable with white text. With 16 colors, the "LightMagenta" is mapped to a bold magenta, which white text shows up much better on.

You can give a quick test by doing something like this:

vimdiff <file1> <file2>
:set t_Co?    " print current setting (256 by default)
:highlight    " print highlighting scheme
:set t_Co=16  " set to 16 colors
:highlight    " print highlighting scheme

256-color screenshot

16-color screenshot

As you can see, the 16 colors is much more readable, without changing the color scheme.

To make this permanent, you can add set t_Co=16 to your .vimrc

回答6:

For people that use the very excellent Solarized theme there's an option that turns on high visibility for diff mode:

" ~/vim.rc
" Set high visibility for diff mode
let g:solarized_diffmode="high"

"normal"

"high"

"low"

回答7:

/etc/vim/vimrc or ~/.vimrc: If using a dark background within the editing area and syntax highlighting turn on this option as well set background=dark

回答8:

molokai: github: The two themes github and molokai are equally beautiful.

curl -fLo ~/.vim/colors/molokai.vim --create-dirs https://raw.githubusercontent.com/tomasr/molokai/master/colors/molokai.vim
curl -fLo ~/.vim/colors/github.vim --create-dirs https://raw.githubusercontent.com/endel/vim-github-colorscheme/master/colors/github.vim

Put the following code in your ~/.vimrc, you can choose github or molokai (a line starting with a " is a comment):

if &diff
"   colorscheme github
    colorscheme molokai
endif

回答9:

Another approach is to fix that color scheme.

As far as I know, there are usually four highlight groups relative to diff'ing: DiffAdd, DiffChange, DiffDelete, and DiffText. If you don't want to be bothered about the syntax or tweaking the colors to your liking, you could probably copy your default color scheme under another name to ~/.vim/colors (create the directory if it doesn't exist) and copy paste the corresponding :hi commands from your alternative color scheme to the end of your new custom color scheme, optionnally commenting out any other diff-related statements therein.

And if the result is an obvious improvement, send an email to the maintainer of your color scheme with your changes and ask him to look into the problem. There's a good chance that he will thank you for your interest and that he will fix his color scheme so that other users will also benefit..

回答10:

I use the following when using vimdiff from within vim:

au BufEnter,BufNew * if &diff | syntax off | else | syntax on | endif

The part with else statement is important because that's how you go back to your previous config after you are done with diff'ing. So you can replace syntax off and syntax on with respective colorscheme commands. This autocmd handles changing a setting and reverting it when quitting vimdiff (I use Gdiff to be precise).

回答11:

my current colorscheme does not show some diffs properly in vimdiff, For. eg some diff is shown with same fg/bg color

Actually, I've found that the main culprit for same fg/bg color is because of conflict between code syntax highlighting and diff colorscheme. You can try to change the diff colorscheme, but it may be a game of whack-a-mole when you open different file types (with different code syntax highlighting).

A sure solution is to disable the syntax highlighting in vimdiff. You can either type:

:syntax off

Or if you want to automatically do this every time, then add this to the end of your ~/.vimrc:

if &diff
    syntax off
endif

回答12:

To expand on @dean and some other answers here, add this to your .vimrc:

if &diff
  " colorscheme evening
  highlight DiffAdd    cterm=bold ctermfg=10 ctermbg=17 gui=none guifg=bg guibg=Red
  highlight DiffDelete cterm=bold ctermfg=10 ctermbg=17 gui=none guifg=bg guibg=Red
  highlight DiffChange cterm=bold ctermfg=10 ctermbg=17 gui=none guifg=bg guibg=Red
  highlight DiffText   cterm=bold ctermfg=10 ctermbg=88 gui=none guifg=bg guibg=Red
endif

来源：https://stackoverflow.com/questions/2019281/load-different-colorscheme-when-using-vimdiff

标签

vim

vimdiff