awk group by multiple columns and print max value with non-primary key

问题

i'm new to this site and trying to learn awk. i'm trying to find the maximum value of field3, grouping by field1 and print all the fields with maximum value. Field 2 contains time, that means for each item1 there is 96 values of field2,field3 and field4

input file: (comma separated)

item1,00:15,10,30
item2,00:45,20,45
item2,12:15,30,45
item1,00:30,20,56
item3,23:00,40,44
item1,12:45,50,55
item3,11:15,30,45

desired output:

item1,12:45,50,55
item2,12:15,30,45
item3,11:15,30,45

what i tried so far:

BEGIN{
FS=OFS=","}
{
if (a[$1]<$3){
   a[$1]=$3}
}
END{
for (i in a ){
print i,a[i]
}

but this only prints

item1,50
item2,30
item3,30

but i need to print the corresponding field2 and field4 with the max value as shown in the desired output. please help.

回答1:

The problem here is that you are not storing the whole line, so when you go through the final data there is no full data to print.

What you need to do is to use another array, say data[index]=full line:

BEGIN{
FS=OFS=","}
{
 if (a[$1]<$3){
   a[$1]=$3
   data[$1]=$0}       # store it here!
}
END {
   for (i in a )
       print data[i]  # print it here
}

Or as a one-liner:

$ awk 'BEGIN{FS=OFS=","} {if (a[$1]<$3) {a[$1]=$3; data[$1]=$0}} END{for (i in a) print data[i]}' file
item1,12:45,50,55
item2,12:15,30,45
item3,23:00,40,44

回答2:

With a little help of the sort command:

sort -t, -k1,1 -k3,3nr file | awk -F, '!seen[$1]++'

回答3:

To do this job robustly you need:

$ cat tst.awk
BEGIN { FS="," }
!($1 in max) {
    max[$1]  = $3
    data[$1] = $0
    keys[++numKeys] = $1
}
$3 > max[$1] {
    max[$1]  = $3
    data[$1] = $0
}
END {
    for (keyNr=1; keyNr<=numKeys; keyNr++) {
        print data[keys[keyNr]]
    }
}

$ awk -f tst.awk file
item1,12:45,50,55
item2,12:15,30,45
item3,23:00,40,44

When doing min/max calculations you should always seed your min/max value with the first value read rather than assuming it'll always be less than or greater than some arbitrary value (e.g. zero-or-null if you skip the !($1 in max) block above).

You need the keys array to preserve input order when printing the output. If you use in instead then the output order will be random.

Note that idiomatic awk syntax is simply:

<condition> { <action> }

not C-style:

{ if ( <condition> ) { <action> } }

来源：https://stackoverflow.com/questions/37523781/awk-group-by-multiple-columns-and-print-max-value-with-non-primary-key

标签

awk

gawk