Clojure closure

Question

the other day I was trying to come up with an example of closure in Clojure. I came up with and example I had seen before and thought it was appropriate.

Alas, I was tol

Answer 1

A closure is a function that has access to some named value/variable outside its own scope, so from a higher scope surrounding the function when it was created (this excludes function arguments and local named values created within the function). Your examples do not qualify, because every function just uses named values from their own scopes.

Example:

(def foo 
  (let [counter (atom 0)]
    (fn [] (do (swap! counter inc) @counter))))

(foo) ;;=> 1
(foo) ;;=> 2
(foo) ;;=> 3, etc

Now foo is a function that returns the value of an atom that is outside its scope. Because the function still holds a reference to that atom, the atom will not be garbage-collected as long as foo is needed.

Answer 2

I wanted to have something that setup constant value(s) that are to be used each time.

(def myran 
  (let [constrand (rand)]
    (fn [n] (* n constrand))))


(myran 3)
2.7124521745892096
(myran 1)
0.9041507248630699
(myran 3)
2.7124521745892096

This will only set a value for "constrand" once. This is a very contrived example, but I wanted to be able to do something like:

This is from: JavaScript: The Good Parts

Answer 3

Function that returns function i.e higher order functions are nice examples of closure.

(defn pow [n]
   (fn [x] (apply * (repeat n x))))

(def sq (pow 2))
(def qb (pow 3))

Answer 4

Another example of closure. There are two functions that share the same environment (state).

(defn create-object [init-state]
  (let [state (atom init-state)]
    {:getter (fn []
               @state)
     :setter (fn [new-val]
               (reset! state new-val))}))

(defn test-it []
  (let [{:keys [setter getter]} (create-object :init-value)]
    (println (getter))
    (setter :new-value)
    (println (getter))))

(test-it)
=> :init-value
   :new-value