How to substring a string in sql server 2008? [closed]

Answer 1

A pretty flexible way to get what you want is by the use of a recursive CTE. The CTE expression will essentially give you the position and the corresponding index of all '/' contained in the string:

DECLARE @string VARCHAR(MAX) = 'CMS/00014456582/693362/004535/JCR_110914_NEW_4535 CMS'

;WITH CTE AS (
    SELECT CHARINDEX('/', @string) AS pos, idx = 1 

    UNION ALL

    SELECT CHARINDEX('/', @string, pos+1) AS pos, idx + 1 
    FROM CTE
    WHERE pos > 0
)
SELECT *
FROM CTE

produces:

pos idx
-------
4   1
16  2
23  3
30  4
0   5

Using the above CTE you can easily extract any part of the string contained within, say, 1st and 2nd slashes, or 2nd and 3rd, etc:

;WITH CTE AS (
    SELECT CHARINDEX('/', @string) AS pos, idx = 1 

    UNION ALL

    SELECT CHARINDEX('/', @string, pos+1) AS pos, idx + 1 
    FROM CTE
    WHERE pos > 0
)
SELECT SUBSTRING(@string, 
                 (SELECT pos FROM CTE WHERE idx = 2) + 1, 
                 (SELECT pos FROM CTE WHERE idx = 3) - (SELECT pos FROM CTE WHERE idx = 2) - 1)

Answer 2

I had wrote a function to split my string data. This can be beneficial for you too :

   CREATE FUNCTION [dbo].[SPLIT]
(
    @ROWDATA NVARCHAR(2000),
    @SPLITON NVARCHAR(5)
)  
RETURNS @RTNVALUE TABLE 
(
    ID INT IDENTITY(1,1),
    DATA NVARCHAR(100)
) 

AS  
BEGIN 
    DECLARE @CNT INT
    SET @CNT =  LEN(@SPLITON)

WHILE (CHARINDEX(@SPLITON,@ROWDATA)>0)
BEGIN
    INSERT INTO @RTNVALUE (DATA)
    SELECT 
        DATA = LTRIM(RTRIM(SUBSTRING(@ROWDATA,1,CHARINDEX(@SPLITON,@ROWDATA)-1)))

    SET @ROWDATA = SUBSTRING(@ROWDATA,CHARINDEX(@SPLITON,@ROWDATA)+1,LEN(@ROWDATA))
    SET @CNT = @CNT + @CNT
END

INSERT INTO @RTNVALUE (DATA)
SELECT DATA = LTRIM(RTRIM(@ROWDATA))

RETURN
END

Create this function And then

SELECT DATA FROM SPLIT ('CMS/00014456582/693362/004535/JCR_110914_NEW_4535 CMS','/');

This will return a table that each row is "/" seperated data of your string.

Answer 3

Thanks for asking Please try the below it helps you if the bold area length isn't always 6 digits

    DECLARE @document varchar(64);
    DECLARE @start int;
    DECLARE @lenght int;
    SELECT @document = 'CMS/00014456582/693362/004535/JCR_110914_NEW_4535 CMS'
    select @start = CHARINDEX('/',@document,CHARINDEX('/',@document)+1)+1
    select @lenght = CHARINDEX('/',@document,CHARINDEX('/',@document,CHARINDEX('/',@document)+1)+1) - @start
    select Substring(@document,@start, @lenght)

Answer 4

DECLARE @Text NVARCHAR(1000)

select @Text = SUBSTRING('CMS/00014456582/693362/004535/JCR_110914_NEW_4535 CMS', CHARINDEX('/', 'CMS/00014456582/693362/004535/JCR_110914_NEW_4535 CMS') + 1,1000) 

SELECT SUBSTRING(@Text, CHARINDEX('/', @Text) + 1,6) AS column_name

Answer 5

this will do if the the string that has to be selected is of fixed length and after 2nd occurance of '/'

DECLARE @document varchar(64);
SELECT @document = 'CMS/00014456582/693362/004535/JCR_110914_NEW_4535 CMS'
select Substring(@document, CHARINDEX('/', @document,(SELECT CHARINDEX('/', @document)+1))+1,6)