How to generate a four day before date in batch script? [closed]

Answer 1

Here is one more convoluted batch way to get the date minus a number of days. This uses a trick with XCOPY to validate that the date is valid.

@echo off
setlocal
set rand=%random%
md "dummy%rand%\empty%rand%"

for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"

set /a y=%dt:~0,4%
set /a m=1%dt:~4,2%
set /a d=1%dt:~6,2%

REM set the number of days to substract
SET DAYS=4
FOR /L %%G IN (1,1,%days%) DO CALL :loop

set subdate=%y%%m:~-2%%d:~-2%
echo %subdate%

rd /s /q "dummy%rand%"
pause
endlocal
GOTO :EOF

:loop
  set /a d-=1

  if %d% lss 101 (
    set d=131
    set /a m-=1

    if %m% lss 101 (
      set m=112
      set /a y-=1
    )
  )

xcopy /d:%m:~-2%-%d:~-2%-%y% /t "dummy%rand%\empty%rand%" "dummy%rand%" >nul 2>&1 || goto loop

GOTO :EOF

Answer 2

To do this in strict Batch, you have to use tokenization or substring extraction on %date%. However, it's problematic because of changes due to locale settings and such. It's even more problematic when you want to get a relative date based on another date, because, as mentioned, there is no understanding in Batch of timespan calculation, considering months, years, leap years, daylight savings, etc.

So the best answer is usually to rely on an external language or library, like JScript in another answer, or my favorite: Powershell.

for /f %%a in ('"powershell [DateTime]::Now.AddDays(-4).ToString('dd-MMM-yy')"') do echo %%a

This is a one-liner that gets the date from Powershell, subtracts 4 days, and puts it in the dd-MMM-yy format as %%a. You can do whatever you want with %%a, and change the format as you like.

Answer 3

I strongly agree with @JosefZ, date math is a complex matter. Vbscript and PowerShell have it incorporated and it is used and depended on like a black box.
Even if batch only has 32bit signed integer math this is sufficient to solve this. When packaged into callable sub routines stored at the end of batches it shouldn't irritate to much.

There is even a method to put them into a batchlibrary somewhere in the path and just a small stub is needed to invoke them.
So here is the variant with only batch code (with massive overhead compared to the powershell one liner) No restrictions to date format and language.

Output:

Today Year: 2016  Month: 12  Day: 08
-38   Year: 2016  Month: 10  Day: 31

Batch

@Echo off
Call :GetDate yy mm dd
Echo Today Year: %yy%  Month: %mm%  Day: %dd%
Set /A n=-38
Call :DateAdd yy mm dd %n%
Echo %n%   Year: %yy%  Month: %mm%  Day: %dd%
Pause
Goto :Eof

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:GetDate yy mm dd
::
:: Func: Loads local system date components into args 1 to 3.
:: 
:: Args: %1 var to receive year,                   4 digits (by ref)
::       %2 var to receive month,     2 digits,    01 to 12 (by ref)
::       %3 Var to receive day of month, 2 digits, 01 to 31 (by ref)
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
SetLocal EnableExtensions
for /f "tokens=1-3 delims=.+-" %%A in (
  'wmic os get LocalDateTime^|findstr ^^[0-9]'
    ) do Set _DT=%%A
Set "yy=%_DT:~0,4%"&Set "MM=%_DT:~4,2%"&Set "dd=%_DT:~6,2%"
endlocal&set %1=%yy%&set %2=%MM%&set %3=%dd%&goto :EOF
:: GetDate.cmd :::::::::::::::::::::::::::::::::::::::::::::::::::::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:DateAdd yy mm dd #days
::
:: Func: Adds/subs Days from/to a given date by converting to a 
::       Julian Day adding the offset and converting back.
:: Args:
::  %1 year  component used to create JD,        4 digits  (by ref)
::  %2 month component used to create JD, leading zero ret (by ref)
::  %3 day of month   used to create MJD, leading zero ret (by ref)
::  %4 days offset may be positive or negative (by val)
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
SetLocal
Call set /A "yy=%%%1%%,mm=100%%%2%% %%%%100,dd=100%%%3%% %%%%100"
Set /A jd=(1461*(yy+4800+(mm-14)/12))/4
Set /A jd=jd+(367*(mm-2-12*((mm-14)/12)))/12
Set /A jd=jd-(3*((yy+4900+(mm-14)/12)/100))/4,jd=jd+dd-32075
Set /A jd=jd+%4
set /A l=jd+68569,n=(4*l)/146097,l=l-(146097*n+3)/4
Set /A i=(4000*(l+1))/1461001,l=l-(1461*i)/4+31,j=(80*l)/2447
Set /A dd=l-(2447*j)/80,l=j/11,mm=j+2-(12*l),yy=100*(n-49)+i+l
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
Endlocal&set %1=%yy%&set %2=%mm%&set %3=%dd%&Goto :Eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

Answer 4

save this with .bat extension:

@if (@x)==(@y) @end /***** jscript comment ******
     @echo off
     cscript //E:JScript //nologo "%~f0" "%~nx0"
     exit /b %errorlevel%

 @if (@x)==(@y) @end ******  end comment *********/

var d = new Date();
d.setDate(d.getDate()-4);
WScript.Echo("berfore 4 days : "+d);

Answer 5

Yes, there are complicated pure Batch file methods that convert a date to Julian Day Number, subtract the number of days and convert the result back to date. There are also other methods that use the date functions of other programming languages, like PowerShell or VBScript/JScript as shown in the other answers.

I hope that the six-line pure Batch method below don't look so complicated.

@echo off
setlocal EnableDelayedExpansion

set N=4

set i=100
for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do set /A "i+=1" & set "dpm[!i!]=%%a"
for /F "tokens=1-3 delims=/" %%a in ("%date%") do (
   set /A "DD=1%%b-N, I=^!(((DD-101)>>31)+1), MM=1%%a-I, J=^!(MM-100), MM+=J*12"
   set /A "YYYY=%%c-J, dpm[102]+=^!(YYYY%%4), DD+=I*dpm[!MM!]"
)
set "newDate=%MM:~1%/%DD:~1%/%YYYY%

echo %newDate%

This method works with a %DATE% format of MM/DD/YYYY; if your date format is different, just change the position of %%a and %%b parameters in the expression and the order of MM and DD in the result.

This method can subtract a maximum of one month from the current date.