mssql 30 minute time intervals beteen 2 datetime

Question

I have below query and i want to get datetime in 30 min intervals between 2 datetime. Basicly I got it, but is limitited and wouln\'t return al results if the timediff is over 2

Answer 1

What about this? You can use variables/ fixed values as necessary.

WITH CTE_Numbers
AS (
    SELECT n = 1

    UNION ALL

    SELECT n + 1
    FROM CTE_Numbers
    WHERE n < 100
    )
SELECT FORMAT(DATEADD(mi, n * 30, '2016/11/03'),'dd-HH:mm')
FROM CTE_Numbers

Answer 2

A tally table is a great way to deal with this type of thing. I keep one in a view to avoid using spt_values.

create View [dbo].[cteTally] as

WITH
    E1(N) AS (select 1 from (values (1),(1),(1),(1),(1),(1),(1),(1),(1),(1))dt(n)),
    E2(N) AS (SELECT 1 FROM E1 a, E1 b), --10E+2 or 100 rows
    E4(N) AS (SELECT 1 FROM E2 a, E2 b), --10E+4 or 10,000 rows max
    cteTally(N) AS 
    (
        SELECT  ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) FROM E4
    )
select N from cteTally

Then your code becomes really simple too. A small amount of datemath and voila.

declare @DateTime1 datetime = '2016/11/24 18:00:00'
    , @DateTime2 datetime = '2016/11/25 06:00:00'

select FORMAT(DATEADD(minute, (t.N - 1) * 30, @DateTime1), 'dd-HH:mm')
from cteTally t
where t.N <= (DATEDIFF(hour, @DateTime1, @DateTime2) * 2) + 1

Answer 3

Please see if this works.

declare @DateTime1 DateTime = '2016-11-24 18:00:00'
declare @DateTime2 DateTime = '2016-11-25 18:00:00'

declare @Interval DateTime = @DateTime1
declare @vartmptable table(DT DateTime)

While (@Interval < @DateTime2)
begin
 --select @Interval, FORMAT(@Interval,'dd-HH:mm')
 insert into @vartmptable select @Interval
 set @Interval = DATEADD(mi,30,@Interval)

end

select FORMAT(DT,'dd-HH:mm')  from @vartmptable

Answer 4

I have a TVF which generates dynamic date/time ranges. It is faster than a recursive cte, and I think more flexible. You pass the date range, desired DatePart, and increment.

Declare @DateTime1 DateTime = '2016-11-24 18:00:00'
Declare @DateTime2 DateTime = '2016-11-25 06:00:00'

Select Format(RetVal,'dd-HH:mm') from [dbo].[udf-Range-Date](@DateTime1,@DateTime2,'MI',30)

Returns

24-18:00
24-18:30
24-19:00
24-19:30
24-20:00
24-20:30
24-21:00
24-21:30
24-22:00
24-22:30
24-23:00
24-23:30
25-00:00
....
25-04:30
25-05:00
25-05:30
25-06:00

The UDF if needed

CREATE FUNCTION [dbo].[udf-Range-Date] (@R1 datetime,@R2 datetime,@Part varchar(10),@Incr int)
Returns Table
Return (
    with cte0(M)   As (Select 1+Case @Part When 'YY' then DateDiff(YY,@R1,@R2)/@Incr When 'QQ' then DateDiff(QQ,@R1,@R2)/@Incr When 'MM' then DateDiff(MM,@R1,@R2)/@Incr When 'WK' then DateDiff(WK,@R1,@R2)/@Incr When 'DD' then DateDiff(DD,@R1,@R2)/@Incr When 'HH' then DateDiff(HH,@R1,@R2)/@Incr When 'MI' then DateDiff(MI,@R1,@R2)/@Incr When 'SS' then DateDiff(SS,@R1,@R2)/@Incr End),
         cte1(N)   As (Select 1 From (Values(1),(1),(1),(1),(1),(1),(1),(1),(1),(1)) N(N)),
         cte2(N)   As (Select Top (Select M from cte0) Row_Number() over (Order By (Select NULL)) From cte1 a, cte1 b, cte1 c, cte1 d, cte1 e, cte1 f, cte1 g, cte1 h ),
         cte3(N,D) As (Select 0,@R1 Union All Select N,Case @Part When 'YY' then DateAdd(YY, N*@Incr, @R1) When 'QQ' then DateAdd(QQ, N*@Incr, @R1) When 'MM' then DateAdd(MM, N*@Incr, @R1) When 'WK' then DateAdd(WK, N*@Incr, @R1) When 'DD' then DateAdd(DD, N*@Incr, @R1) When 'HH' then DateAdd(HH, N*@Incr, @R1) When 'MI' then DateAdd(MI, N*@Incr, @R1) When 'SS' then DateAdd(SS, N*@Incr, @R1) End From cte2 )

    Select RetSeq = N+1
          ,RetVal = D 
     From  cte3,cte0 
     Where D<=@R2
)
/*
Max 100 million observations -- Date Parts YY QQ MM WK DD HH MI SS
Syntax:
Select * from [dbo].[udf-Range-Date]('2016-10-01','2020-10-01','YY',1) 
Select * from [dbo].[udf-Range-Date]('2016-01-01','2017-01-01','MM',1) 
*/

Answer 5

using a recursive Common Table Expression [CTE] is one pretty clean method. For the formatting I am showing FORMAT() from SQL-Server 2012+ you may consider using DATEPART etc to do it though as FORMAT() can have performance impact.

I do agree with @RossBush's comment if you do things like this a lot generating a calendar (dates) and a time dimensions is very helpful for these purposes.

DECLARE @DateTime1 DATETIME = '2016/11/24 18:00:00'
DECLARE @DateTime2 DATETIME = '2016/11/25 06:00:00'

;WITH cte30MinIncrements AS (
    SELECT @DateTime1 as DT

    UNION ALL

    SELECT DATEADD(MINUTE,30,DT)
    FROM
       cte30MinIncrements
    WHERE DATEADD(MINUTE,30,DT) <= @DateTime2
)

SELECT
    *
    ,FORMAT(DT,'dd-HH:mm') as Formated
FROM
    cte30MinIncrements