items in array A that are not in array B [duplicate]

Answer 1

Not a one liner, but this is likely to be faster than yours on big arrays:

#!/usr/bin/perl
use warnings;
use 5.012;

sub difference {
    my ($first, $second) = @_;
    my %except;
    @except{ @$second } = 1;
    return [ grep { not exists $except{$_} } @$first ];
}

my @anames = ("one", "two", "three", "four", "five");
my @hrefs = ("two", "four", "six");

my $d = difference \@anames, \@hrefs;
say "@$d";

Answer 2

If you know which array contains the other

my @small  = 10..12;
my @large  = 10..15;

my %ref = map { $_ => 1 } @small;

my @diff = grep { not exists $ref{$_} } @large;

Not quite one line but efficient.

If it's not known which contains the other then one has to do it both ways.

And then there are various modules for array/list manipulation that can help.

For one, get_complement from List::Compare does precisely what is needed.

---

What you have can be done in one statement, using List::Util

use List::Util qw(none);

my @diff = grep { my $e = $_; none { $e eq $_ } @small } @large; 

but this has O(NM-M²/2) complexity, where N (large) and M (small) are array sizes.