Grouping XML nodes by attribute value in XSLT

Question

Im quite new to xslt transforms and I need help with one kind of transformation. I need to group all nodes of certain type by one of it atributes and list parents of every k

Answer 1

You could try the following approach?

<!-- select the current child id to filter by -->
<xsl:variable name="id" select="somechild/@child-id"/>
<!-- select the nodes which have a somechild element with the child-id to look for -->
<xsl:for-each select="/root//some-child[@child-id = $id]/..">
   <!-- for each such node, do something -->
</xsl:for-each>

Answer 2

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:key name="k" match="somechild" use="@child-id"/>
    <xsl:key name="n" match="node" use="somechild/@child-id"/>

    <xsl:template match="root">
        <xsl:copy>
            <xsl:apply-templates 
                select="//somechild[generate-id(.) = generate-id(key('k', @child-id))]"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="somechild">
        <xsl:copy>
            <xsl:apply-templates select="@*"/>

            <is-child-of>
                <xsl:apply-templates select="key('n', @child-id)"/>
            </is-child-of>
        </xsl:copy>

    </xsl:template>

    <xsl:template match="node">
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*">
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

Output:

<root>
  <somechild child-id="1">
    <is-child-of>
      <node name="node1" />
      <node name="node3" />
    </is-child-of>
  </somechild>
  <somechild child-id="2">
    <is-child-of>
      <node name="node2" />
      <node name="node4" />
    </is-child-of>
  </somechild>
  <somechild child-id="3">
    <is-child-of>
      <node name="node5" />
    </is-child-of>
  </somechild>
</root>