Populate XML template-file from XPath Expressions?

Question

What would be the best way to populate (or generate) an XML template-file from a mapping of XPath expressions?

The requirements are that we will need to start with a

Answer 1

This transformation creates from the "expressions" an XML document that has the structure of the wanted result -- it remains to transform this result into the final result:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:my="my:my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vPop" as="element()*">
    <item path="/create/article[1]/id">1</item>
    <item path="/create/article[1]/description">bar</item>
    <item path="/create/article[1]/name[1]">foo</item>
    <item path="/create/article[1]/price[1]/amount">00.00</item>
    <item path="/create/article[1]/price[1]/currency">USD</item>
    <item path="/create/article[1]/price[2]/amount">11.11</item>
    <item path="/create/article[1]/price[2]/currency">AUD</item>
    <item path="/create/article[2]/id">2</item>
    <item path="/create/article[2]/description">some name</item>
    <item path="/create/article[2]/name[1]">some description</item>
    <item path="/create/article[2]/price[1]/amount">00.01</item>
    <item path="/create/article[2]/price[1]/currency">USD</item>
 </xsl:variable>

 <xsl:template match="/">
  <xsl:sequence select="my:subTree($vPop/@path/concat(.,'/',string(..)))"/>
 </xsl:template>

 <xsl:function name="my:subTree" as="node()*">
  <xsl:param name="pPaths" as="xs:string*"/>

  <xsl:for-each-group select="$pPaths"
    group-adjacent=
        "substring-before(substring-after(concat(., '/'), '/'), '/')">
    <xsl:if test="current-grouping-key()">
     <xsl:choose>
       <xsl:when test=
          "substring-after(current-group()[1], current-grouping-key())">
         <xsl:element name=
           "{substring-before(concat(current-grouping-key(), '['), '[')}">

          <xsl:sequence select=
            "my:subTree(for $s in current-group()
                         return
                            concat('/',substring-after(substring($s, 2),'/'))
                             )
            "/>
        </xsl:element>
       </xsl:when>
       <xsl:otherwise>
        <xsl:value-of select="current-grouping-key()"/>
       </xsl:otherwise>
     </xsl:choose>
     </xsl:if>
  </xsl:for-each-group>
 </xsl:function>
</xsl:stylesheet>

When this transformation is applied on any XML document (not used), the result is:

<create>
   <article>
      <id>1</id>
      <description>bar</description>
      <name>foo</name>
      <price>
         <amount>00.00</amount>
         <currency>USD</currency>
      </price>
      <price>
         <amount>11.11</amount>
         <currency>AUD</currency>
      </price>
   </article>
   <article>
      <id>2</id>
      <description>some name</description>
      <name>some description</name>
      <price>
         <amount>00.01</amount>
         <currency>USD</currency>
      </price>
   </article>
</create>

Note:

1. You need to transform the "expressions" you are given into the format used in this transformation -- this is easy and straightforward.

2. In the final transformation you need to copy every node "as-is" (using the identity rule), with the exception that the top node should be generated in the "http://predic8.com/wsdl/material/ArticleService/1/" namespace. Note that the other namespaces present in the "template" are not used and can be safely ommitted.

Answer 2

This solution requires you to re-organise your XPATH input information slightly, and to allow a 2-step transformation. The first transformation will write the stylesheet, which will be executed in the second transformation - Thus the client is required to do two invocations of the XSLT engine. Let us know if this is a problem.

Step One

Please re-organise your XPATH information into an XML document like so. It should not be difficult to do, and even an XSLT script could be written to do the job.

<paths>
 <rule>
  <match>article[1]/id[1]</match>
  <namespaces>
   <namespace prefix="ns1">http://predic8.com/wsdl/material/ArticleService/1/</namespace>
   <!-- The namespace node declares a namespace that is used in the match expression.
        There can be many of these. It is not required to define the s11: namespace,
        nor the ns1 namespace. -->
  </namespaces>
  <replacement>1</replacement>
 </rule> 
 <rule>
  <match>article[1]/description[1]</match>
  <namespaces/>
  <replacement>bar</replacement>
 </rule>
 ... etc ...
</paths>

Solution constraints

In the above rules document we are constrained so that:

1. The match is implicitly prefixed 'expression: /create/'. Don't put that explicitly.
2. All matches must begin like article[n] where n is some ordinal number.
3. We can't have zero rules.
4. Any prefixes that you use in the match, other than s11="http://schemas.xmlsoap.org/soap/envelope/" and ns1="http://predic8.com/wsdl/material/ArticleService/1/". (Note: I don't think it is valid for namespaces to end in '/' - but not sure about that), are defined in the namespaces node.

The above is the input document to the step one transformation. Apply this document to this style-sheet ...

<xsl:stylesheet version="2.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:step2="http://www.w3.org/1999/XSL/Transform-step2"
      xmlns:s11="http://schemas.xmlsoap.org/soap/envelope/"                       
      xmlns:ns1="http://predic8.com/wsdl/material/ArticleService/1/"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes='xsl'>
<xsl:output method="xml" indent="yes" encoding="UTF-8" />
<xsl:namespace-alias stylesheet-prefix="step2" result-prefix="xsl"/>

<xsl:template match="/">
 <step2:stylesheet version="2.0">
 <step2:output method="xml" indent="yes" encoding="UTF-8" />

  <step2:variable name="replicated-template" as="element()*">
   <step2:apply-templates select="/" mode="replication" />
  </step2:variable>

  <step2:template match="@*|node()" mode="replication">
     <step2:copy>
        <step2:apply-templates select="@*|node()" mode="replication" />
     </step2:copy>
  </step2:template>

  <step2:template match="/s11:Envelope/s11:Body/ns1:create/article" mode="replication">
   <step2:variable name="replicant" select="." />  
    <step2:for-each select="for $i in 1 to
       {max(for $m in /paths/rule/match return
        xs:integer(substring-before(substring-after($m,'article['),']')))}
          return $i">
   <step2:for-each select="$replicant">
       <step2:copy>
        <step2:apply-templates select="@*|node()" mode="replication" />
       </step2:copy>
      </step2:for-each>   
     </step2:for-each>    
  </step2:template>

  <step2:template match="@*|node()">
   <step2:copy>
    <step2:apply-templates select="@*|node()"/>
   </step2:copy>
  </step2:template> 

  <step2:template match="/">
   <step2:apply-templates select="$replicated-template" />
  </step2:template>

  <xsl:apply-templates select="paths/rule" /> 
 </step2:stylesheet>
</xsl:template>

<xsl:template match="rule">
 <step2:template match="s11:Envelope/s11:Body/ns1:create/{match}">
  <xsl:for-each select="namespaces/namespace">
   <xsl:namespace name="{@prefix}" select="." />
  </xsl:for-each>
  <step2:copy>
   <step2:apply-templates select="@*"/>
   <step2:value-of select="'{replacement}'"/>
   <step2:apply-templates select="*"/>
  </step2:copy>
 </step2:template>
</xsl:template>

</xsl:stylesheet>

Step Two

Apply your soap envelope file, as an input document, to the style-sheet which was output from step one. The result is the original soap document, altered as required. This is a sample of a step two style-sheet, with just the first rule (/create/article[1]/id => 1) being considered for the sake of simplicity of illustration.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:s11="http://schemas.xmlsoap.org/soap/envelope/"
                version="2.0">
   <xsl:output method="xml" indent="yes" encoding="UTF-8"/>
   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
   <xsl:template xmlns:ns1="http://predic8.com/wsdl/material/ArticleService/1/"
                 match="/s11:Envelope/s11:Body/ns1:create[1]/article[1]/id[1]">
      <xsl:copy>
         <xsl:apply-templates select="@*"/>
         <xsl:value-of select="'1'"/>
         <xsl:apply-templates select="*"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

More solution constraints

1. The template document must contain at least one /s11:Envelope/s11:Body/ns1:create/article . Only the article node is replicated (deeply) as required by rules. Other than than it can be any structure.
2. The template document cannot contain nested levels of the s11:Envelope/s11:Body/ns1:create node.

Explanation

You will notice that your XPATH expressions are not far removed from a match condition of template. Therefore it is not too difficult to write a stylesheet which re-expresses your XPATH and replacement values as template rules. When writing a style-sheet writing style-sheet the xsl:namespace-alias enables us to disambiguate "xsl:" as an instruction and "xsl:" as intended output. When XSLT 3.0 comes along, we are quiet likely to be able to reduce this algorithm into one step, as it will allow dynamic XPATH evaluation, which is really the nub of your problem. But for the moment we must be content with a 2-step process.

The second style-sheet is a two-phase transformation. The first stage replicates the template from the article level, as many times as needed by the rules. The second phase parses this replicated template, and applies the dynamic rules substituting text values as indicated by the XPATHs.

---

UPDATE

My original post was wrong. Thanks to Dimitre for pointing out the error. Please find updated solution above.

After-thought

If a two-step solultion is too complicated, and you are running on a wintel platform, you may consider purchasing the commercial version of Saxon. I believe that the commercial version has a dynamic XPATH evaluation function. I can't give you such a solution because I don't have the commercial version. I imagine a solution using an evaluate() function would be a lot simpler. XSLT is just a hobby for me. But if you are using XSLT for business purposes, the price is quiet reasonable.