Using variables for asc and desc in order by [duplicate]

Answer 1

Try this one -

DECLARE 
      @column VARCHAR(15) = 'object_id'
    , @order CHAR(4) = 'DESC'

DECLARE @SQL NVARCHAR(MAX)
SELECT @SQL = '
SELECT * 
FROM sys.objects 
ORDER BY ' + @column + ' ' + @order

PRINT @SQL
EXEC sys.sp_executesql @SQL

Answer 2

without Dynamic SQL each option it's clause for example:

ORDER BY
  case when @var1 = 'priority asc' THEN priority END ASC ,
  case when @var1 = 'priority desc' then priority end DESC,
  case when @var2 = 'report_date asc' then report_date end ASC,
  case when @var2 = 'report_date desc' then report_date end DESC

Answer 3

You can sort dynamically on many types by introducing a multiplier hack to the Order by. The implementation will depend on you being able to convert each sortable field to an integer field, like so:

DECLARE @Var1 NVARCHAR(20);
DECLARE @Var2 NVARCHAR(3);
DECLARE @OrderHack INT;

SET @Var1 = 'priority';
SET @Var2 = 'DESC';

IF (@Var2 = 'ASC')
    SET @OrderHack = 1;
ELSE
    SET @OrderHack = -1;

SELECT * 
    FROM SortTable
    ORDER BY 
        CASE @var1
            WHEN 'priority'
                THEN CONVERT(INT, [priority]) * @OrderHack
            WHEN 'report_date'
                THEN CONVERT(INT, report_date) * @OrderHack
        END;

SqlFiddle here

Edit

Just to clarify, as per @t-clausen.dk's point, the hack is dependent on a a conversion back to a increasing numeric type representing the order. e.g. if you require higher resolution on a DATETIME to ensure that the time component is also considered in the sort, the INT @OrderHack can be replaced with a FLOAT or DECIMAL etc. Caveat : Using this technique to sort on *CHAR columns could be challenging, especially if case and accent sensitivity is taken into account.

Answer 4

Assuming your variable @var3 stores 'ASC' or 'DESC' keywords, you can write something like this:

order by 
case when @var1 = 'priority' and @var3 = 'DESC' then priority end DESC,
case when @var1 = 'priority' and @var3 = 'ASC' then priority  end ASC,
case when @var2 = 'report_date' and @var3 = 'ASC' then report_date end ASC,
case when @var2 = 'report_date' and @var3 = 'DESC' then report_date end DESC