How to repeat string n times in idiomatic clojure way?

Question

In Ruby, \"str\" * 3 will give you \"strstrstr\". In Clojure, the closest I can think of is (map (fn [n] \"str\") (range 3)) Is there a more idioma

Answer 1

I wouldn't claim this is idiomatic, but it is also possible to repeat a string using the clojure cl-format function which clojure inherited from common lisp. Common lisp in turn transplanted it from FORTRAN which came up with this piece of work in the 50s.

And here we are in 2018...

Example:

user=> (cl-format nil "~v@{~a~:*~}" 5 "Bob")
"BobBobBobBobBob"

The format string works as follows:

• the first format specifier is ~5@{ where the five is pulled from the argument list since there is a v in front of the @. the ~5@{ in turn means iterate 5 times using the entire argument list (the string "Bob") as the iterable.
• inside the curlies (the curly expression is ended by the ~}), we print the string "Bob" with ~a and then "move the argument pointer" back one position using the ~:* construct so that we can "consume" the argument "Bob" again.

Voila, 5 repetitions of Bob.

It should be noted that cl-format can either return the produced string (if the second argument is nil), print it to the current *out* (if the second argument is true), or print it to a writer (if the second argument is a writer).

For the all too gory details on the format string syntax you can refer to:

Formatted Output to Character Streams

in the common lisp the language reference and possibly to:

Eliminating format from lisp

for why it could be argued that cl-format is a bad idea.

Answer 2

How about this?

(apply str (repeat 3 "str"))

Or just

(repeat 3 "str")

if you want a sequence instead of a string.

Answer 3

And one more fun alternative using protocols:

(defprotocol Multiply (* [this n]))

Next the String class is extended:

(extend String Multiply {:* (fn [this n] (apply str (repeat n this)))})

So you can now 'conveniently' use:

(* "foo" 3)

Answer 4

Just to throw some more awesome and hopefully thought-provoking solutions.

user=> (clojure.string/join (repeat 3 "str"))
"strstrstr"

user=> (format "%1$s%1$s%1$s" "str")
"strstrstr"

user=> (reduce str (take 3 (cycle ["str"])))
"strstrstr"

user=> (reduce str (repeat 3 "str"))
"strstrstr"

user=> (reduce #(.concat %1 %2) (repeat 3 "str"))
"strstrstr"

Answer 5

Or use the repeat function that comes with clojure-contrib' string package. In that case you can use (clojure.contrib.string/repeat 3 "str") which results in "strstrstr".

Answer 6

unidiomatic solution : (ie : DON'T EVER DO THIS)

((fn [[x & xs]] (apply (eval x) xs)) (repeat 4 'str))