How to create self-extracting RAR archive not showing anything on execution?

Question

I am trying to create a self-extracting archive that extracts to \"%USERPROFILE%\\Desktop\" with WinRar. However, when I run it, it extracts to the SFX\'s current directory,

Answer 1

Mofi! I think here a problem:

Change the following

"-z%TEMP%\SfxOptions.txt"

To the following

-z "%TEMP%\SfxOptions.txt"

Answer 2

It is possible to create an SFX RAR archive extracting all files and folders directly to
"%USERPROFILE%\Desktop" without showing a window.

This can be done with WinRAR after selecting the files and folders and clicking on icon Add in the toolbar by

1. checking on tab General the option Create SFX archive,
2. clicking on tab Advanced on button SFX options,
3. entering on SFX tab General for Path to extract the string "%USERPROFILE%\Desktop" which results in automatic selection of option Absolute path which is right,
4. selecting on SFX tab Modes the option Hide all,
5. selecting on SFX tab Module the SFX module Default.sfx (WinRAR GUI SFX module),
6. closing Advanced SFX options window with button OK,
7. entering on tab General the name for the SFX archive,
8. and starting compression with button OK.

A command prompt window will be always displayed if module WinCon.sfx is used for the SFX archive as in this case Windows detects automatically on start of the SFX archive that this is a console application and opens a command prompt window in which the console SFX is executed.

Creating such an SFX archive can be done also with a batch file:

@echo off
echo ;The comment below contains SFX script commands>"%TEMP%\SfxOptions.txt"
echo/>>"%TEMP%\SfxOptions.txt"
echo Path="%%USERPROFILE%%\Desktop">>"%TEMP%\SfxOptions.txt"
echo Silent=^1>>"%TEMP%\SfxOptions.txt"
"%ProgramFiles%\WinRAR\Rar.exe" a -c -cfg- -ep1 -idq -m5 -mdg -r -s -sfx -y "-z%TEMP%\SfxOptions.txt" "Path\Name of your SFX.exe" "Path\Folder to add" "Path\File to add"
if errorlevel 1 goto Failure
del "%TEMP%\SfxOptions.txt"
goto :EOF

:Failure
del "%TEMP%\SfxOptions.txt"
echo/
echo Error on creation of "Path\Name of your SFX.exe"
echo/
pause

In this batch file must be modified for usage:

1. Path to program files folder of WinRAR containing console version Rar.exe and also the SFX module Default.sfx.
2. Path and name of the SFX archive to create.
3. Path and name of folder and/or file to add to the archive.

The used switches are explained in text file Rar.txt in program files folder of WinRAR.

One more note on switch -ep1:

Everything up to last backslash in name of folder and/or file to add to archive is removed from name on adding the folder or file to the archive.

On adding a folder to a RAR archive it makes a difference if the folder is specified with or without a backslash at end.

Example:

A directory tree like

• C:\Temp
  • MyFolder
    • Subfolder 1
    • Subfolder 2
      • File X
    • File Y

is compressed with

Rar.exe a -ep1 -r C:\Temp\Demo1.rar C:\Temp\MyFolder

with following files and folders in archive C:\Temp\Demo1.rar

• MyFolder
  • Subfolder 1
  • Subfolder 2
    • File X
  • File Y

while using

Rar.exe a -ep1 -r C:\Temp\Demo2.rar C:\Temp\MyFolder\

or using

Rar.exe a -ep1 -r C:\Temp\Demo2.rar C:\Temp\MyFolder\*

results in following files and folders in archive C:\Temp\Demo2.rar

• Subfolder 1
• Subfolder 2
  • File X
• File Y