How to get unique values in a column using excel formula

Question

I have Excel Data like below

       JID     Val

       1001    22
       1030    6
       1031    14          
       1041    8
       1001    3
       2344             


        

Answer 1

Here is a solution to get a list of unique items from your tables

There is two parts to this solution.

Part 1) Unique Count

{=SUM(IF(FREQUENCY(IF($A$2:$A$10<>"",MATCH($A$2:$A$10,$A$2:$A$10,0)),ROW($A$2:$A$10)-ROW($A$2)+1),1))}

This will count the number of unique items in your data table and will ignore any blanks

*Note this is an array formula and you will need to use "Ctrl" + "Shift" + "Enter" to use

Part 2) Unique List

This formula will give you the list of unique items in your table

={IF(ROWS($E$5:E5)>$E$2,"",INDEX($A$2:$A$10,SMALL(IF(FREQUENCY(IF($A$2:$A$10<>"",MATCH($A$2:$A$10,$A$2:$A$10,0)),ROW($A$2:$A$10)-ROW($A$2)+1),ROW($A$2:$A$10)-ROW($A$2)+1),ROWS($E$5:E5))))}

again this is an array formula. You can then drag this formula down to get all the unique items.

This formula is a dynamic formula, meaning you can set the data range past your current data range and the list will update as you enter new values.

*Here is a great video to watch to understand this further

https://www.youtube.com/watch?v=3u8VHTvSNE4

Answer 2

I think I've found a more elegant workaround without array-functions or built-in functions:

• 1^st column (ID):
  this is the array from we'd like to select distinct values

• 2^nd column (criteria): checks whether this is the first occurrence
  =IF((ROW()-1)=MATCH(A2,$A$2:$A$500,0),1,0)

• 3^rd column (cumulative):
  =SUM($B$2:B2)

• 4^th column (count):
  this is constant 1

• 5^th column (unique ID):
  =OFFSET($A$2,MATCH(ROW()-1,$C$2:$C$501,0)-1,)

• 6^th column (count):
  =SUMIF(A2:A21,F2,D2:D21)

Answer 3

You can use the remove duplicate function

Select the column range

Go to Data Tab

then click on Remove Duplicates