What does :: (double colon) mean in DOS batch files?

Question

I found this program http://baiyunmanor.com/blog/work/get-current-date-time-in-dos-batch-file/

But I don\'t know what does the line

:: datetime.bat
<         


        

Answer 1

A line that start in double colon represent an invalid label that is ignored by the command processor, so it may be used to insert a comment. For reasons that can't be traced, many people use :: to insert comments in Batch files, but you must be aware that there are several pitfalls in its use that are described in the link given in Koterpillar's answer. It seems that the first use of :: instead of REM command was with the purpose to speed up the execution of Batch files in slow machines (ie: floppy disks), but that reason is not a valid justification for the use of double colon since many years ago.

Any line that contain an invalid label will be ignored by the command processor and you may use practically any special character to generate an invalid label. For example:

@echo off

:~ This is a comment
:` This is a comment
:! This is a comment
:@ This is a comment
:# This is a comment
:$ This is a comment
:% This is a comment
:^ This is a comment
:& This is a comment
:* This is a comment
:( This is a comment
:) This is a comment
:_ This is a comment
:- This is a comment
:+ This is a comment
:= This is a comment
:{ This is a comment
:} This is a comment
:[ This is a comment
:] This is a comment
:| This is a comment
:\ This is a comment
:: This is a comment
:; This is a comment
:" This is a comment
:' This is a comment
:< This is a comment
:> This is a comment
:, This is a comment
:. This is a comment
:? This is a comment
:/ This is a comment

echo OK

In other words: if you want to insert a comment and you want not to use REM command (although I can't think of any reason to do so), you have 32 possible character combinations to do so. Why you should use precisely this one: ::? Just because some old programs written 35 years ago did it?

Answer 2

:: is a label (also, inaccurately, known in the wild by comment label) can be, in practice, considered a comment just as REM is, as it is an "un-goto-able" label.

There are some differences between REM and ::, though. The main ones are:

• With ECHO ON a REM line is shown but not a line commented with ::

• A :: can execute a line end caret (that is, a ^ at the end of a line starting with :: makes the next line also a comment):

  :: This is a comment^
  echo but watch out because this line is a comment too
  

• Labels and :: have a special logic and can cause problems in parentheses blocks - take care when using them inside ( ). Example:

  for %%D in (hi) do (
      echo Before...
      :: My comment
      :: Some other comment
      echo After...
  )
  

  Outputs:

  Before ...
  The system cannot find the drive specified.
  After...
  

Answer 3

The colon (:) is a label marker and can be used for got instructions.

Some people use : as a comment too so a double colon is simply a stylistic REM statement

Answer 4

As mentioned by acdcjunior Labels and :: have a special logic and can cause problems in parenthesis blocks

Here are couple of samples

Sample 1

IF 1==1 (
  ::
)

Output of sample 1

) was unexpected at this time.

Sample 2

IF 1==1 (
  ::
  ::
)

Output of sample 2

The system cannot find the drive specified.

Answer 5

A line starting with a colon is a label which you can jump to with goto:

goto end
:end

A line starting with a double colon is a label, except you can't, even accidentally, jump to it:

goto :end REM this doesn't work
::end

Thus, double colon is used to comment lines out.

Source: http://www.robvanderwoude.com/comments.php